在 VBA 中打开 CSV 文件时如何保持前导零

Question

我有一个 VBA 代码可以快速从 CSV 文件传输数据，但不幸的是排除了前导零（例如 000123 转换为 123）

Filename = "c:\text.csv"
Dim wbI As Workbook, wbO As Workbook
Dim wsI As Worksheet
Set wbI = ThisWorkbook
Set wsI = wbI.Sheets("Temp")
Filename = "c:\text.csv"

Set wbO = Workbooks.Open(Filename) 
wbO.Sheets(1).Cells.Copy wsI.Cells
wbO.Close SaveChanges:=False

我尝试打开csv文件后添加以下内容> Cells.NumberFormat = "@"

Set wbO = Workbooks.Open(Filename) 
Cells.NumberFormat = "@"
wbO.Sheets(1).Cells.Copy wsI.Cells
wbO.Close SaveChanges:=False

不幸的是，它不起作用，我看到的问题是文件打开后已经缺少前导零

是否可以在不影响前导零的情况下打开文件并将所有数据显示为文本以保持前导零？

Answer 1

请试试这个方法：

Sub testOpenWithLZeroTxt()
 Dim Filename As String, wbI As Workbook, wbO As Workbook, wsI As Worksheet
 Dim arrTXT, nrCol As Long, arr(), i As Long, sep As String, lineSep As String
 Dim allTxt As String, txtStr As Object, fileTxt As String, fs As Object, f As Object, ts As Object
 
 Set wbI = ThisWorkbook
 Set wsI = wbI.Sheets("Temp")
 Filename = "c:\text.csv"
    fileTxt = Split(Filename, ".")(0) & ".txt" 'create a helper txt file using the csv string content
    
    Set fs = CreateObject("Scripting.FileSystemObject")
    allTxt = fs.OpenTextFile(Filename, 1).ReadAll 'reed the csv file content
    fs.CreateTextFile fileTxt
    Set f = fs.GetFile(fileTxt)
    Set ts = f.OpenAsTextStream(2, -2)
        ts.write allTxt                          'write the csv content in a newly created txt file
    ts.Close
    
    'Check the number of text file columns:_______
    sep = vbLf ' if not working you can try vbCrLf. It works so on your file
    lineSep = ","  'it my be vbTab, ";" etc. It works so on your file
    arrTXT = Split(allTxt, sep)
    nrCol = UBound(Split(arrTXT(0), lineSep))
    '_____________________________________________
    
    ReDim arr(nrCol) 'redim the format array
    For i = 0 To nrCol
        arr(i) = Array(i + 1, 2) 'fill the format array with variant for TEXT Format!
    Next
    'open the helper txt file as you need:
    Workbooks.OpenText Filename:=fileTxt, origin:=437, startRow:=1, _
                DataType:=xlDelimited, Tab:=False, Comma:=True, FieldInfo:=arr()
    Set wbO = ActiveWorkbook
    'wbO.Sheets(1).cells.Copy wsI.Range("A1") 'copy the content
    wbO.Close SaveChanges:=False              'close the file
    Kill fileTxt                              'kill helper txt file
End Sub

已编辑：

我改变了代码理念。它将首先读取字符串变量中的 csv 内容，并使用获得的字符串创建一个 txt 文件并将其作为文本打开，这当然应该可以工作。它适用于 csv 文件中的任意数量的列。

Answer 2

您的 csv 文件中的换行符是 unix LF。这对应于 chr(10)。

由于第一行的列数和下一行的列数不一致，所以使用了一点偏差。通过将第一行的列数加倍来创建一个数组。

Sub test()
    Dim Ws As Worksheet
    Dim Fn As String
    Dim Arr As Variant
    
    Fn = "Example.csv"
    'Fn = "c:\text.csv"
    Set Ws = Sheets("Temp")
    
    Arr = getDatFromCsv(Fn)
    
    With Ws
        .Cells.NumberFormat = "@"
        .Cells = Empty
        .Range("a1").Resize(UBound(Arr, 1) + 1, UBound(Arr, 2) + 1) = Arr
    End With
    
    
End Sub
Function getDatFromCsv(strFn As String) As Variant
    Dim vR() As String
    Dim i As Long, r As Long, j As Integer, c As Integer
    Dim objStream  As Object
    Dim strRead As String
    Dim vSplit, vRow
    Dim s As String
    
    Set objStream = CreateObject("ADODB.Stream")

    With objStream
        .Charset = "utf-8"
        .Open
        .LoadFromFile strFn
         strRead = .ReadText
        .Close
    End With
    
    vSplit = Split(strRead, Chr(10)) 'Unix Lf ~~> chr(10)
    r = UBound(vSplit)
    c = UBound(Split(vSplit(0), ",", , vbTextCompare))
    ReDim vR(0 To r, 0 To c * 2)
    
    For i = 0 To r
        vRow = Split(vSplit(i), ",", , vbTextCompare)
        'If UBound(vRow) = c Then 'if it is empty line, skip it
            
            For j = 0 To UBound(vRow)
                vR(i, j) = vRow(j)
            Next j
        'End If
    Next i
    getDatFromCsv = vR
    
    Set objStream = Nothing

End Function

结果图片

Answer 3

请改用OpenText method。

最重要的参数是FieldInfo。你需要通过：

包含单个数据列的解析信息的数组。解释取决于 DataType 的值。当数据被分隔时，这个参数是一个二元素数组的数组，每个二元素数组指定特定列的转换选项。第一个元素是列号（从 1 开始），第二个元素是 XlColumnDataType 常量之一，指定如何解析列。

换句话说，每列前导零，都必须定义为xlTextFormat。

我建议录制宏。 ;) 加载文本数据的选项，您可以在Data 选项卡下找到 -> ... -> From text/CSV