Excel VBA范围

Question

对于下面的代码，我设置的范围似乎没有出来。 基本上我想连接从 A2 到 A23 的值。我的数据进入单元格 A24。

我将单元格 A24 命名为“WrapNarrEnd”，因为有时我想添加额外的行，所以我希望“WrapNarrEnd”保持不变。我尝试在“WrapNarrEnd”之前使用偏移值到达单元格一一切正常，直到倒数第二行，我不确定我哪里出错了。有人可以帮帮我吗？

Function ConcatMe(Rng As Range) As String
    Dim cl As Range
    ConcatMe = ""
    For Each cl In Rng
        ConcatMe = ConcatMe & " " & cl.Text
    Next cl
End Function

---

Sub test2()
    Dim WrapNarrative As Range
    Dim WrapEnd As Range
    Set WrapEnd = Sheets("CA Sweeps").Range("WrapNarrEnd").Offset(-1, 0)
    **Set WrapNarrative = Sheets("CA Sweeps").Range("A2:wrapnarrend")**
    Sheets("CA Sweeps").Range("I24").Value = ConcatMe(WrapNarrative)
End Sub

示例图片：

Answer 1

范围引用的语法错误。你需要Range(<TopLeftCell>, <BottomRightCell>)

另外，您的ConactMe 功能可以得到改进。

这是你的代码，重构

Function ConcatMe(Rng As Range, Optional Sep As String = vbNullString) As String
    Dim dat As Variant

    If Rng.Columns.Count = 1 Then
        dat = Application.Transpose(Rng.Value)
        ConcatMe = Join(dat, Sep )
    ElseIf Rng.Rows.Count = 1 Then
        dat = Application.Transpose(Application.Transpose(Rng.Value))
        ConcatMe = Join(dat, Sep )
    Else
        ' what do you want to do now?
    End If
End Function


Sub test2()
    Dim WrapNarrative As Range
    Dim WrapEnd As Range

    With Sheets("CA Sweeps")
        Set WrapEnd = .Range("WrapNarrEnd").Offset(-1, 0)
        Set WrapNarrative = .Range("A2", "wrapnarrend")
        .Range("I24").Value = ConcatMe(WrapNarrative, " ")
    End With
End Sub