命令提示符/Bat 文件 - 创建以今天日期命名的新文件夹答案

【问题标题】：Command Prompt/Bat file - Create new folder named with today's date命令提示符/Bat 文件 - 创建以今天日期命名的新文件夹
【发布时间】：2013-06-19 06:25:13
【问题描述】：

我使用以下代码创建一个以今天日期命名的新文件夹：

for /f "tokens=1* delims=" %%a in ('date /T') do set datestr=%%a
mkdir c:\%date:/=%

现在格式如下：

20130619

如何将格式更改为？：

2013_06_19

谢谢

【问题讨论】：

标签： command-line batch-file

【解决方案1】：

%date% 取决于您的计算机设置和区域设置。这是获取日期和时间戳的可靠方法。 Win XP pro 及以上版本。

如果您需要在未知机器上使用您的批处理文件，那么这值得使用。

:: time and date stamp YYYYMMDD, HHMMSS and YYYY-MM-DD_HH-MM-SS
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set datestamp=%dt:~0,8%
set timestamp=%dt:~8,6%
set YYYY=%dt:~0,4%
set MM=%dt:~4,2%
set DD=%dt:~6,2%
set HH=%dt:~8,2%
set Min=%dt:~10,2%
set Sec=%dt:~12,2%

set stamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%
echo stamp: "%stamp%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"

pause

【讨论】：

终于有人不依赖依赖于语言环境的 %date% 了！

【解决方案2】：

for /f "tokens=1-3 delims=/" %%a in ("%date%") do md "%%a_%%b_%%c"

【讨论】：

【解决方案3】：

这样做：

for /F "tokens=2-4 delims=/ " %%i in ('date /t') do set yyyymmdd1="%%k"_"%%i"_"%%j"
mkdir %yyyymmdd1%

【讨论】：

取自可能对您有所帮助的先前答案，stackoverflow.com/questions/11280077/… - 看看我如何操纵“%%i”或 %%k 或 %%j 以及它们之间的 _
谢谢，但您的回答只显示文件夹名称中的月份和日期，而不是年份...测试一下
嗨，它显示了这一切，也许你没有复制粘贴整行:) 我的回答是你接受的那个。它是相同的和原始的

【解决方案4】：

或者干脆

SET Today=%Date:~10,4%_%Date:~7,2%_%Date:~4,2%

echo %today%

输出

2013_06_19
Press any key to continue . . .

那么您今天可以轻松地使用该变量来创建目录，例如：

mkdir %today%

编辑：YYYY_MM_DD 格式

【讨论】：

使用您当前的代码，它将“今天”作为文件夹名称返回
是的，这不是您想要的吗？您可以连接驱动器号或路径的其他部分。此解决方案不包含任何 for 循环