VBA - 如何搜索活动工作簿，并将文件名与字符串匹配？

Question

我正在编写一个用于工作的快速自动化项目，我无法指定用于打开工作簿的文件路径，因为它用于特殊软件中，VBA 不容易访问。

如果用户 A 打开此文件：“ABC_todaysdate”... 我将如何告诉 Excel 循环浏览活动工作簿（用户 A 可以打开 5-6 个工作簿），在 Activeworkbook 文件名中找到字母 ABC，然后使用在我的其他职能中？

到目前为止的 VBA 代码：

Sub CopyDemand()
Dim filename As String
Dim Wb As Workbook
Dim ws As Worksheet
Dim Wb2 As Workbook

Set Wb = ThisWorkbook
For Each Wb2 In Application.Workbooks
filename = ActiveWorkbook.FullName
If filename Like "demand" Then
Debug.Print ("Found")
''' Insert function to use WB2 and copy over data, compare workbooks etc.
Next
Wb.Activate

End Sub

Answer 1

您可以迭代每个工作簿，但我认为这里的关键是使工作簿处于活动状态，以便您可以使用路径信息检索 FullName。

Option Explicit

Function getWbName(SearchStr As String) As String
On Error GoTo ErrHand:
    Application.ScreenUpdating = False
    Dim wb As Workbook

    getWbName = vbNullString

    For Each wb In Workbooks
        If InStr(1, wb.Name, SearchStr, vbTextCompare) > 0 Then
            wb.Activate
            getWbName = ActiveWorkbook.FullName
            Exit For
        End If
    Next

    'Return the active window and exit
    ThisWorkbook.Activate
    Application.ScreenUpdating = True
    Exit Function

ErrHand:
    Application.ScreenUpdating = True
    MsgBox (Err.Number & " has occured, with description: " & Err.Description)
End Function

Sub Example()
    Debug.Print getWbName("Book2")
End Sub

编辑

更新了上面的代码，改为返回 WorkBook 对象。

Option Explicit

Function getWorkBookByName(SearchStr As String) As Workbook
    Dim wb As Workbook

    For Each wb In Workbooks
        If InStr(1, wb.Name, SearchStr, vbTextCompare) > 0 Then
            Set getWorkBookByName = wb
            Exit Function
        End If
    Next
End Function

Sub Example()
    Dim myWb As Workbook: Set myWb = getWorkBookByName("Book2")
    If Not myWb Is Nothing Then Debug.Print myWb.FullName
End Sub

Answer 2

您可以尝试捕获Application对象的WorkbookOpen事件。

这是一种方法：将以下代码复制到主工作簿的ThisWorkbook 对象中。

Option Explicit

Private WithEvents myApp As Application

Private Sub myApp_WorkbookOpen(ByVal Wb As Workbook)
    MsgBox "Openned " & Wb.FullName
End Sub

Private Sub Workbook_Open()
    Set myApp = Application
End Sub

然后关闭您的工作簿并在启用宏的情况下重新打开。此工作簿的名称以及打开时打开的每个后续工作簿都将显示在消息框中。