使用 XSLT 将多个同名元素包装成一个新元素

Question

我正在尝试使用 XSLT 重新格式化一些 XML。我输入的 sn-p 如下所示：

<toggles>
  <toggle toggleDisplayName="Charges">
    <anotherElement attribute="value" />
    <gridColumn sourceField.name="FIELD1" />
    <gridColumn sourceField.name="FIELD2" />
    <gridColumn sourceField.name="FIELD3" />
  </toggle>
</toggles>

我想将所有“gridColumn”元素包装成一个“网格”元素，如下所示：

<toggles>
  <toggle toggleDisplayName="Charges">
    <anotherElement attribute="value" />
    <grid>
      <gridColumn sourceField.name="FIELD1" />
      <gridColumn sourceField.name="FIELD2" />
      <gridColumn sourceField.name="FIELD3" />
    </grid>
  </toggle>
</toggles>

我当前的 XSLT 是：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:msxsl="urn:schemas-microsoft-com:xslt"
     exclude-result-prefixes="msxsl">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="toggle/gridColumn">
    <grid>
      <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
    </grid>
  </xsl:template>

  <!--Identity transform for remaining-->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

现在这种工作，但我得到每个 'gridColumn' 元素在它自己的 'grid' 元素。是否有任何简单的方法可以修改它，以便我可以获得上述结果？

注意：已编辑以阐明输入 XML。

提前感谢您的帮助！

Answer 1

我能想到的最简单的变体，如果所有 gridColumn 元素在原始输入 XML 中都是相邻的（形成一个没有其他干预元素的连续块），则该变体有效：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:strip-space elements="*" />
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="toggle">
    <xsl:copy>
      <!-- apply templates to everything except the second and subsequent
           gridColumn child elements -->
      <xsl:apply-templates select="@* | node()[not(self::gridColumn)]
                                      | gridColumn[1]" />
    </xsl:copy>
  </xsl:template>

  <!-- this template will be called for just the first gridColumn within
       a toggle... -->
  <xsl:template match="gridColumn">
    <grid>
      <!-- ... and will gather all its sibling gridColumn elements under the
           new grid element -->
      <xsl:copy-of select="../gridColumn" />
    </grid>
  </xsl:template>

  <!--Identity transform for remaining-->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

如果gridColumn 元素不是全部相邻，您会发现它们都已在第一个 gridColumn 出现在输入 XML。

Answer 2

我想出了这个解决方案。请检查它是否满足您的所有要求。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output method="xml" indent="yes" />

  <!-- Process toggle separately, because its childredn cannot simply be copied -->
  <xsl:template match="toggle">
    <xsl:copy>
      <xsl:apply-templates select="./@*" /> <!-- For some unknown reason I needed this -->
      <xsl:apply-templates />
      <grid>
        <xsl:for-each select="gridColumn">
          <xsl:copy-of select="." />
        </xsl:for-each>
      </grid>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="gridColumn">
    <!-- Do nothing, because it is processed by for-each -->
  </xsl:template>

  <!--Identity transform for remaining-->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>