使用批处理文件重置环境变量答案

【问题标题】：Reset environment variable with batch file使用批处理文件重置环境变量
【发布时间】：2014-12-04 12:53:44
【问题描述】：

我想重置除列表中的环境变量之外的所有环境变量。

我试试这个：

@echo OFF
SETLOCAL ENABLEDELAYEDEXPANSION
set notToChange=APPDATA PATH
for /f "delims=" %%i in ('set') do (
    for /f "delims==" %%j in ("%%i") do (
        set "var=%%j"
    )
    if "%notToChange%"=="%notToChange:!var!=%" (
        set !var!=
    )
)

我有一个问题：

if "%notToChange%"=="%notToChange:!var!=%"

它不起作用。我不明白为什么。

【问题讨论】：

就算能做到，也好像是个坏主意
确实如此。似乎重新启动会更安全。 :)
当您想要测试软件并验证您的包中是否包含所有库时，它非常有用。

标签： batch-file environment-variables

【解决方案1】：

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
set "notToChange=APPDATA PATH"
for /f "delims==" %%i in ('set') do IF /i "%%i" neq "nottochange" IF /i "%nottochange%" equ "!nottochange:%%i=!" ECHO clear %%i

GOTO :EOF

我建议在执行此例程时要格外小心。我只是评论说要清除该变量（set "%%i=" 应该清除它，如果这是您真正想要做的...）

nottochange 不需要在不要更改我的列表中。

【讨论】：

notToChange变量本身的问题很重要。

【解决方案2】：

扩展没有按您希望的方式运行。
您需要使用另一个 FOR-Loop 才能替换该变量。
附加循环将变量var复制到参数%%V

@echo OFF
setlocal EnableDelayedExpansion
set "notToChange=APPDATA PATH notToChange"
for /f "delims=" %%i in ('set') do (
    for /f "delims==" %%j in ("%%i") do (
        set "var=%%j"
    )

    for /F "delims=" %%V in ("!var!") do (
          if "!notToChange:%%~V=!" == "!notToChange!" (
              set "!var!="
          )
    )
)

看了Magoo的解决方案，我意识到notToChange变量的问题，所以我添加了一些代码来避免这个问题

顺便说一句。这将只删除批处理文件中的变量，因为在结束后setlocal 将被endlocal 隐式还原，恢复所有变量

【讨论】：

【解决方案3】：

set "notToChange=APPDATA PATH"
for /f "delims==" %%a in ('set') do (
    set "remove=1"
    for %%b in (%notToChange%) do if /i "%%a"=="%%b" set "remove="
    if defined remove set "%%a=" & set "remove="
)
set

看到已经发布的代码，我不知道我是否遗漏了什么，但这应该可以工作。

已编辑 是的，我没有看到的是它并不像我想象的那么容易。比较容易

(
    for /f "delims==" %%a in ('set') do  set "%%a="
    set "PATH=%path%"
    set "APPDATA=%appdata%"
)
set

已编辑。如果您想继续使用配置变量，这也将起作用

set "notToChange=APPDATA PATH"

for /f "delims==" %%a in ('set') do (
    setlocal enabledelayedexpansion
    if not defined notToChange set "notToChange=%notToChange%"
    for /f "delims=" %%b in ("!notToChange:%%a=!=") do (
        endlocal 
        if /i "%notToChange%=" equ "%%b" set "%%a="
    )
)
set

【讨论】：