调用子运行时错误“424”时出错：需要对象

Question

大图

1. 浏览一个列表并为列表中的每个项目创建一个选项卡（工作）
2. 在列表中创建一个超链接，链接到相关工作表 (Working)
3. 在每个工作表上创建基本标题信息并超链接回索引表（工作）
4. 为索引表中相应单元格中列出的每个参考文献插入一个按钮，并超链接到该 pdf、doc 或 docx 文件（不工作，正在进行中）

当前问题

当调用将插入按钮的 sub 时，我收到 Object Required 错误（见最后的图片）。

主要部分代码如下：

Sub CreateTabs()

Dim ws As Worksheet
Dim NameArray As Variant
Dim LastRow As Long
Dim x As Long
Dim y As Long
Dim z As Long
Dim ReferenceCount As Long
Dim RefSplit() As Variant

    LastRow = FindLastRow
    Set ws = ThisWorkbook.Sheets(1)
    NameArray = ws.Range(ws.Cells(2, 1), ws.Cells(LastRow, 1)).Value
    For x = LBound(NameArray) To UBound(NameArray)
        ThisWorkbook.Sheets.Add(after:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count)).Name = NameArray(x, 1)
        'ws.Hyperlinks.Add ws.Cells(x + 1, 1), "", ThisWorkbook.Sheets(NameArray(x, 1)).Cells(1, 1).Address(External:=True), NameArray(x, 1), NameArray(x, 1)
        With ThisWorkbook.Sheets(NameArray(x, 1))
            ws.Hyperlinks.Add ws.Cells(x + 1, 1), "", .Cells(1, 1).Address(External:=True), .Name, .Name
            .Hyperlinks.Add .Cells(1, 1), "", ws.Cells(1, 1).Address(External:=True), "Item List", "ITEM LIST"
            .Cells(2, 1) = "Item"
            .Cells(3, 1) = "Description"
            .Cells(4, 1) = "U.O.M."
            .Cells(6, 1) = "Specifications"
            .Cells(2, 2).Formula = "=RIGHT(CELL(""filename"",$B$2),LEN(CELL(""filename"",$B$2))-FIND(""]"",CELL(""filename"",$B$2)))"
            .Cells(3, 2).Formula = "=VLOOKUP($B$2,Sheet1!$A$2:$D$" & LastRow & ",2,0)"
            .Cells(4, 2).Formula = "=VLOOKUP($B$2,Sheet1!$A$2:$D$" & LastRow & ",4,0)"
            
            ReferenceCount = Num_Characters_In_String(ws.Cells(x + 1, 3).Value, ", ") + 1
            ReDim RefSplit(1 To ReferenceCount,1)
            If ReferenceCount > 1 Then
                RefSplit = ReferenceSplit(ws.Cells(x + 1, 3).Value)
            Else
                RefSplit(1,1) = ws.Cells(x + 1, 3).Value
            End If
            
            z = 1
            
            For y = 1 To ReferenceCount
                If y > z * 5 Then z = z + 1
'*************************************************************
                Call Insertbutton(z, y - (z - 1) * 5, RefSplit(y, 1).Value, ThisWorkbook.Sheets(NameArray(x, 1)))
'*************************************************************
            Next y
                
        End With
    Next x
End Sub

被调用的子现在看起来如下：

Sub Insertbutton(btnrow As Long, btncol As Long, btnName As String, ws As Worksheet)

Dim btn As Button
Dim rng As Range

    Application.ScreenUpdating = False
    ws.Buttons.Delete 'probably do not need as it is fresh sheet

    Set rng = ws.Cells(btnrow + 6, btncol + 1)
    Set btn = ws.Buttons.Add(rng.Left, rng.Top, rng.Width, rng.Height)
    
    With btn
        If Left(btnName, 1) = "F" Then
            If Num_Characters_In_String(btnName, "-") = 2 Then
                .OnAction = "P:\2019\1234-name space\08. Working\Specifications\Section F" & btnName & "*.doc*"
            Else
                .OnAction = "P:\2019\1234-name space\10. Construction\01. Tender\F\" & btnName & ".pdf"
            End If
        Else
            .OnAction = "P:\2019\1234-name space\10. Construction\01. Tender\OPSS\OPSS*" & btnName & "*.pdf"
        End If
        .Caption = btnName
        .Name = btnName
    End With
    Application.ScreenUpdating = True

End Sub

问题

丢失的对象是什么？我在通话中做错了什么？

（我预见到链接到文件时会出现一些问题，但我在调试中还没有到那个地步，这将是一个不同的问题。可以这么说，尽量不要弄脏水）

我确实阅读了this question，所以我相信调用 () 的格式是正确的，但我可能是错误的

Answer 1

RefSplit(y, 1).Value 会导致错误。 RefSplit(y, 1) 是正确的。

不要将 .value 用于数组。因为是用于范围对象，所以会发生对象错误。

Call Insertbutton(z, y - (z - 1) * 5, RefSplit(y, 1).Value, ThisWorkbook.Sheets(NameArray(x, 1)))

但是，还有一个错误，无法匹配参数的类型。应该使用字符串变量。

Dim myString As String
myString = RefSplit(y, 1)
Call Insertbutton(Z, y - (Z - 1) * 5, myString, ThisWorkbook.Sheets(NameArray(x, 1)))