邮件合并为 PDF 而不是打印

Question

我使用电子表格页面 Excel 提示中的教程：邮件合并 - 没有 Word 为 100 条记录创建邮件合并样式报告。使用记录索引和来自另一个工作表的间接查找都可以很好地生成我需要的报告。

我希望将每个输出保存为使用合并中的字段命名的 PDF，而不是打印。我尝试将“ActiveSheet.PrintOut”替换为“ActiveSheet.ExportasFixedFormat”并输入 PDF 规范。它在一定程度上起作用，因为我能够在指定位置生成 PDF，但它只会生成一个 PDF，而不是我试图创建的整个范围。

这是我尝试使用的代码。我查看了其他答案，了解如何遍历每条记录以创建单独的 PDF，但一次只能生成一个 PDF。

Public Const APPNAME As String = "Progress Report"

Option Explicit

Sub PrintForms()
    Dim StartRow As Integer
    Dim EndRow As Integer
    Dim Msg As String
    Dim HRETID As String
    Dim i As Integer

Sheets("ProgressReport").Activate
StartRow = Range("StartRow")
EndRow = Range("EndRow")
HRETID = Range("HRETID")

 If StartRow > EndRow Then
    Msg = "ERROR" & vbCrLf & "The starting row must be less than the ending row!"
    MsgBox Msg, vbCritical, APPNAME
End If

For i = StartRow To EndRow
    Range("RowIndex") = i
        ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:="C:\Users\ewilliamson\PDFs\" & HRETID, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False
Next i
End Sub

Answer 1

如果您希望文件名是动态的，那么您需要在循环内从HRETID 中获取值，而不是只在循环外获取一次：

For i = StartRow To EndRow
    Range("RowIndex") = i
        ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:="C:\Users\ewilliamson\PDFs\" & _
                   Range("HRETID").Value & ".pdf", _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False
Next i

Answer 2

您的 filename:= 分配中的 HRETID 值似乎没有改变。 （为此，需要为循环中的每一行分配一个新值）

如果您想遍历一列以将该列中单元格的值分配给 HRETID，请尝试以下操作：

Dim rItem as Range

for each ritem in Range("HRETID")
   ActiveSheet.ExportAsFixedFormat _
    Type:=xlTypePDF, _
    Filename:="C:\Users\ewilliamson\PDFs\" & ritem.value , _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, _
    IgnorePrintAreas:=False

next rItem

请注意，您不需要将 HRETID 作为字符串，因为您可以从 rItem 获取单元格值。