存储过程错误处理 - 清理但返回原始错误

Question

我正在编写一个存储过程，如果insert 失败，它需要清理一些数据。我希望它执行清理，但如果此插入失败，则返回原始错误（主要用于记录，因为我想确切地了解 insert 失败的原因）。基本上就像C# 中的throw;。有没有一种简单的方法可以做到这一点？

BEGIN TRY
    Insert into table (col1) values ('1")
END TRY
BEGIN CATCH
    --do clean up here
    --then throw original error
END TRY

这是可行/好的做法吗？在调用 proc 的应用程序代码中，我从应用程序的角度处理错误，但清理语句似乎更适合 proc 内部。

Answer 1

我通常会这样做：

IF EXISTS (SELECT * FROM dbo.sysobjects WHERE id = object_id(N'[dbo].[procedure_name]') AND ObjectProperty(id, N'IsProcedure') = 1)
    DROP PROCEDURE [dbo].[procedure_name]
GO

CREATE PROCEDURE [dbo].[procedure_name]
(
    @param1 VARCHAR(100)
   ,@param2 INT
)

AS

/*
*******************************************************************************
<Name>
[procedure_name]
</Name>

<Purpose>
[Purpose]
</Purpose>

<Notes>
</Notes>

<OutsideRef>
Called From: [Called From]
</OutsideRef>

<ChangeLog>
Change No:   Date:          Author:       Description:                          
_________    ___________    __________    _____________________________________
   001       [DATE]         [YOU]         Created.                           
</ChangeLog>
*******************************************************************************
*/
BEGIN
    SET NOCOUNT ON
    SET XACT_ABORT OFF -- Allow procedure to continue after error

    -- *****************************************
    -- Parameter string. Used for error handling
    -- *****************************************
    DECLARE  @ErrorNumber       INT 
            ,@ErrorMessage      VARCHAR(400)
            ,@ErrorSeverity     INT
            ,@ErrorState        INT
            ,@ErrorLine         INT
            ,@ErrorProcedure    VARCHAR(128)
            ,@ErrorMsg          VARCHAR(2000)
            ,@NestedProc        BIT = 1
            ,@Params            VARCHAR(255);    -- String representing parameters, make it an appropriate size given your parameters.

    --Be Careful of the CONVERT here, GUIDs (if you use them) need 36 characters, ints need 10, etc.        
    SET @Params = ''
                + CHAR(13) + '@param1 = ' + COALESCE(CONVERT(VARCHAR(100), @param1), 'NULL') 
                + CHAR(13) + '@param2 = ' + COALESCE(CONVERT(VARCHAR(10), @param2), 'NULL')

    BEGIN TRY
        --If you're using transactions, and want an 'all or nothing' approach, use this so that
        --you only start a single transaction in the outermost calling procedure (or handle 
        --that through your application layer)
        IF @@TRANCOUNT = 0
        BEGIN
            SET @NestedProc = 0
            BEGIN TRANSACTION
        END

        INSERT INTO [TABLE]
            (
             COL1
            ,COL2
            )
        VALUES
            (
             @param1
            ,@param2
            );

        --Commit the transaction if this is the outtermost procedure and if there is a transaction to rollback.
        IF @@TRANCOUNT > 0 AND @NestedProc = 0
        BEGIN
            COMMIT TRANSACTION
        END
    END TRY

    BEGIN CATCH
        --Roll back the transaction if this is the outtermost procedure and if there is a transaction to rollback.
        IF @@TRANCOUNT > 0 AND @NestedProc = 0
        BEGIN
            ROLLBACK TRANSACTION
        END

        -- Execute the error retrieval routine.
        SELECT 
            @ErrorNumber = ERROR_NUMBER(),
            @ErrorSeverity = ERROR_SEVERITY(),
            @ErrorProcedure = ERROR_PROCEDURE(),
            @ErrorState = ERROR_STATE(),
            @ErrorLine = ERROR_LINE(),
            @ErrorMessage = ERROR_MESSAGE();

        SET @ErrorMsg = 'Error Number   : ' + CAST(@ErrorNumber AS VARCHAR(5)) + CHAR(13)
                      + 'Procedure Name : ' + @ErrorProcedure + CHAR(13)
                      + 'Procedure Line : ' + CAST(@ErrorLine AS VARCHAR(5)) + CHAR(13)
                      + 'Error Message  : ' + @ErrorMessage + CHAR(13)
                      + 'Parameters     : ' + CHAR(13) + @Params + CHAR(13);

        --Raise the exception.
        RAISERROR (@ErrorMsg, @ErrorSeverity, @ErrorState);
    END CATCH
END
GO

这种类型的过程允许您使用事务嵌套过程（只要期望的效果是，如果在任何地方抛出错误，您最终会返回到外部过程然后回滚）。我认为这个模板无法处理的一个非常重要的场景是抛出一个严重到足以完全终止该过程的错误的情况。也许其他人可以在这方面加入。

Answer 2

假设我们使用的表 MyTable 定义为

CREATE TABLE [dbo].[MyTable](
    [Col1] [int] NOT NULL
) ON [PRIMARY]

我将使用类似于以下的过程。

在插入失败的情况下，代码将进入 Catch 块，在那里可以执行和分配错误号/消息的检查。

一旦分配了事务，就可以回滚并返回错误号/消息。

您可能需要更改 RAISERROR 错误行中的 SQL Server 错误编号，具体取决于您正在执行的操作。

CREATE PROCEDURE [dbo].[zTestProc]

AS
BEGIN

    SET NOCOUNT ON;
    DECLARE 
            @LocalError     INT,
            @ErrorMessage   VARCHAR(4000)

    BEGIN TRY
        BEGIN TRANSACTION TestTransaction

        Insert into MyTable(col1) values ('01/01/2002')


        COMMIT TRANSACTION TestTransaction

    END TRY
    BEGIN CATCH

        SELECT  @LocalError     =   ERROR_NUMBER(),
                @ErrorMessage   =   ERROR_MESSAGE()

        IF( XACT_STATE()) <>0
        BEGIN
            ROLLBACK TRANSACTION TestTransaction
        END

        RAISERROR ('TestSP: %d: %s', 16, 1, @LocalError, @ErrorMessage) ;
        RETURN(0)

    END CATCH


END

Answer 3

试试下面的 sn-p。

DECLARE @errNum int
DECLARE @rowCount int

BEGIN TRY
    INSERT INTO [TABLE] (COL1) VALUES ('1")
END TRY
BEGIN CATCH
    SET @errNum = @@ERROR
    SET @rowCount = @@ROWCOUNT
    RAISEERROR(@errNum)
END CATCH