数组的 Perl 哈希和一些问题

Question

我目前有一个如下所示的 csv 文件：

a,b
a,d
a,f
c,h
c,d

所以我将它们保存到一个哈希中，这样键“a”是一个带有“b，d，f”的数组，而键“c”是一个带有“h，d”的数组......这就是我用于：

while(<$fh>)
{
 chomp;
 my @row = split /,/;
 my $cat = shift @row;
 $category = $cat      if (!($cat eq $category))  ;
 push @{$hash{$category}}, @row;
}

close($fh);

不确定效率，但是当我进行数据转储时它似乎可以工作......

现在，我遇到的问题是；我想为每个键创建一个新文件，并且在每个文件中我想打印键中的每个元素，如下所示：

文件“a”看起来像这样：

b
d
f

<end of file>

有什么想法吗？我尝试过的一切都不起作用，我对哈希不太熟悉/经验丰富......

提前致谢:)

Answer 1

使用each迭代器的输出过程非常简单，它在一次调用中为下一个哈希元素提供键值对

use strict;
use warnings;
use autodie;

open my $fh, '<', 'myfile.csv';

my %data;

while (<$fh>) {
   chomp;
   my ($cat, $val) = split /,/;
   push @{ $data{$cat} }, $val;
}

while (my ($cat, $values) = each %data) {
   open my $out_fh, '>', $cat;
   print $out_fh "$_\n" for @$values;
}

Answer 2

#!/usr/bin/perl

use strict;
use warnings;

my %foos_by_cat;

{
   open(my $fh_in, '<', ...) or die $!;
   while (<$fh_in>) {
      chomp;
      my ($cat, $foo) = split /,/;
      push @{ $foos_by_cat{$cat} }, $foo;
   }
}

for my $cat (keys %foos_by_cat) {
   open(my $fh_out, '>', $cat) or die $!;
   for my $foo (@{ $foos_by_cat{$cat} }) {
      print($fh_out "$foo\n");
   }
}

我写了内部循环，以显示读写之间的对称性，但也可以写成如下：

print($fh_out "$_\n") for @{ $foos_by_cat{$cat} };