dbpedia SPARQL 查询以获取给定城市的特定值

Question

我确信我想做的事情很简单，但我似乎无法正确查询。我在数据集中有记录，这些记录具有诸如城市名称之类的值。 'New York' 和它对应的国家代码，例如'US'。我还可以访问完整的国家/地区名称和国家/地区 ISO 代码。

我想从 dbpedia 中获取这些城市的人口和抽象值，方法是使用 where 子句，例如：

Get population where name = "New York" and isoCountryCode = "US"

我已经在这方面寻求帮助，但无济于事。

到目前为止，@rohk 帮助我解决了这个问题，但它并不完全适用于所有位置：

SELECT DISTINCT ?city ?abstract ?pop
WHERE {
   ?city rdf:type schema:City ;
     rdfs:label ?label ;
     dbpedia-owl:abstract ?abstract ;
     dbpedia-owl:country ?country ;
     dbpedia-owl:populationTotal ?pop .
   ?country dbpprop:countryCode "USA"@en .
   FILTER ( lang(?abstract) = 'en' and regex(?label, "New York City"))
 }

以上适用于纽约，但是当我将其更改为：

SELECT DISTINCT ?city ?abstract ?pop
WHERE {
   ?city rdf:type schema:City ;
         rdfs:label ?label ;
         dbpedia-owl:abstract ?abstract ;
         dbpedia-owl:country ?country ;
         dbpedia-owl:populationTotal ?pop .
   ?country dbpprop:countryCode "THA"@en .
   FILTER ( lang(?abstract) = 'en' and regex(?label, "Bangkok"))
}

它没有返回泰国曼谷的结果。

我似乎无法正确获取 SPARQL 查询，我确定我的查询很愚蠢。如果任何大师可以为我提供帮助，我将不胜感激。谢谢！

Answer 1

我猜你想要这样的东西：

SELECT * WHERE {
  ?x rdfs:label "New York City"@en.
  ?x dbpedia-owl:populationTotal ?pop.
  ?x dbpedia-owl:abstract ?abstract.
}

要仅获取英文摘要，请添加FILTER：

SELECT * WHERE {
  ?x rdfs:label "New York City"@en.
  ?x dbpedia-owl:populationTotal ?pop.
  ?x dbpedia-owl:abstract ?abstract.
  FILTER (LANG(?abstract) = 'en')
}

“纽约”是州，没有附上populationTotal 数字。 “纽约市”就是这座城市。

Answer 2

此查询有效

SELECT DISTINCT *
WHERE {
   ?city rdf:type schema:City ;
         rdfs:label ?label ;
         dbpedia-owl:abstract ?abstract ;
         dbpedia-owl:country ?country ;
         dbpprop:website ?website ;
         dbpedia-owl:populationTotal ?pop .
   ?country dbpprop:countryCode "USA"@en .
   FILTER ( lang(?abstract) = 'en' and regex(?label, "New York City"))
}

编辑：对于曼谷，有两个问题：

• 泰国没有国家代码：您可以改用rdfs:label "Thailand"@en。
• 曼谷的rdf:type 不是schema:City 而是dbpedia-owl:Settlement

这是曼谷的有效查询

SELECT DISTINCT *
WHERE {
   ?city rdf:type dbpedia-owl:Settlement ;
         rdfs:label "Bangkok"@en ;
         dbpedia-owl:abstract ?abstract ;
         dbpedia-owl:populationTotal ?pop ;
         dbpedia-owl:country ?country ;
         dbpprop:website ?website .
   ?country rdfs:label "Thailand"@en .
   FILTER ( lang(?abstract) = 'en' )
}