如何为批量传递给脚本的逗号分隔参数申请循环？

Question

我有一个文件夹列表如下：

• C:\Program 文件
• C:\temp
• C:\约翰·斯诺

我必须将逗号分隔的参数传递给脚本，如下所示：

script.bat C:\Program Files,C:\temp,C:\John Snow

传递给脚本后，我需要过滤掉逗号分隔的参数并应用每个循环并回显参数值并执行 dir 命令以列出该目录中的文件

Answer 1

@ECHO OFF
SETLOCAL EnableExtensions
set "_params=%*"
if not defined _params (
  echo %~nx0: nothing to do
  pause
  exit /B
)
set "_params=%_params:,=","%"
for %%G in ("%_params%") do (
  echo dir "%%~G"
)

输出

==> 37321331.bat
37321331.bat: nothing to do
Press any key to continue . . .

==> 37321331.bat C:\Program Files,C:\temp,C:\John Snow
dir "C:\Program Files"
dir "C:\temp"
dir "C:\John Snow"

==>

上面的脚本需要一些详细说明：如果某些参数包含在一对双引号中，它将失败：

==> 37321331.bat C:\Program Files,C:\temp,"C:\John Snow"
dir "C:\Program Files"
dir "C:\temp"
dir ""C:\John"
dir "Snow"""

编辑。使用下一个代码 sn-p 修复它：set "_params=%_params:"=%" 将从提供的字符串中删除所有 " 双引号。

set "_params=%_params:"=%"
set "_params=%_params:,=","%"
for %%G in ("%_params%") do (
  echo dir "%%~G"
)

资源（必读，不完整）：

• （命令参考）An A-Z Index of the Windows CMD command line
• （附加特性）Windows CMD Shell Command Line Syntax
• (%~G,%*等专页)Command Line arguments (Parameters)
• （%variable:StrToFind=NewStr% 等）Variable Edit/Replace

Answer 2

set "args=%*"
set "args=%args:,=","%"
for %%# in ("%args%") do (
  dir "%%~#"
)

试试这个。