在批处理文件的参数中转义字符，如 "、<、>、>> 或 |

Question

尝试做：

fake-command.bat "ping -n 4 -w 1 127.0.0.1 >NUL"

和

fake-command.bat ping -n 4 -w 1 127.0.0.1

批处理文件可能如下所示：

@echo %*

它应该返回：

ping -n 4 -w 1 127.0.0.1 >NUL

和

ping -n 4 -w 1 127.0.0.1

这里有一个解决方法：

@echo off
goto start
------------------------------------------------------

Usage : mystring <command>

  Quotes around the command are required only when the
  command involves redirection via <, >, >>, or |, etc.
  Quotes ensure that the redirection is applied to the 
  command, rather than the bat command itself.

Examples :

  mystring ping -n 4 -w 1 127.0.0.1
  mystring "ping -n 4 -w 1 127.0.0.1 >NUL"

------------------------------------------------------
:start
SETLOCAL ENABLEDELAYEDEXPANSION

SET "MYSTRING=%*"
ECHO My String = !MYSTRING!
SET !MYSTRING=MYSTRING:>=^>!

CALL :BATCH_FUNCTION !MYSTRING!
GOTO :EOF

:BATCH_FUNCTION
SET "ARGS=%~1"
ECHO Arguments = !ARGS!
endlocal
GOTO :EOF

问题在于：mystring "ping -n 1 127.0.0.1 >NUL"

返回：

My String =
Arguments =

及之后：mystring ping -n 1 127.0.0.1

返回：

My String = ping -n 1 127.0.0.1
Arguments = ping

更新： 我用Get list of passed arguments in Windows batch script (.bat)的以下代码更新了这个问题

@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
if exist param.txt (del param.txt)
for %%a in ('%*') do (
    set "prompt="
    echo on
    for %%b in ('%*') do rem * #%~1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo My string is = !param1!

使用此代码，我可以获得转义字符，但参数不在引号中的输出被破坏

什么有效？

mystring "# % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^ " &REM OK
mystring "ping -n 4 -w 1 127.0.0.1 >NUL" &REM OK

返回：

My string is = # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^
My string is = ping -n 4 -w 1 127.0.0.1 >NUL 

什么不起作用？

mystring ping -n 4 -w 1 127.0.0.1 &REM NOK
mystring "*" &REM NOK

返回：

My string is = ping
The system can not find the file param.txt.
My string is = *

我看不出如何在这段代码中添加the trick from Mofi。

Answer 1

同样适用于单个参数"ping -n 4 -w 1 127.0.0.1 >NUL"的批处理代码是：

@echo off
goto start
------------------------------------------------------

Usage : mystring <command>

  Quotes around the command are required only when the
  command involves redirection via <, >, >>, or |, etc.
  Quotes ensure that the redirection is applied to the
  command, rather than the bat command itself.

Examples :

  mystring ping -n 4 -w 1 127.0.0.1
  mystring "ping -n 4 -w 1 127.0.0.1 >NUL"

------------------------------------------------------
:start
SETLOCAL ENABLEDELAYEDEXPANSION

if "%~2" == "" (SET "MYSTRING=%~1") else (SET "MYSTRING=%*")
ECHO My String = !MYSTRING!
SET "!MYSTRING=MYSTRING:>=^>!"

CALL :BATCH_FUNCTION "!MYSTRING!"
GOTO :EOF

:BATCH_FUNCTION
SET "ARGS=%~1"
ECHO Arguments = !ARGS!
endlocal
GOTO :EOF

一开始的 IF 条件有重要的区别。

当调用批处理文件时

fake-command.bat ping -n 4 -w 1 127.0.0.1

它使用 6 个参数调用，因此 %* 是将所有参数分配给变量 MYSTRING 的正确方法。

但是用

调用批处理文件

fake-command.bat "ping -n 4 -w 1 127.0.0.1 >NUL"

表示只有 1 个用双引号括起来的参数传递给批处理文件。

线

SET "MYSTRING=%*"

导致将字符串分配给变量MYSTRING

"ping -n 4 -w 1 127.0.0.1 >NUL"

在字符串中包含引号。剩余的引号会导致进一步处理的错误结果。

不清楚应该为变量ARGS 分配什么。如果传递给批处理文件的所有参数都应分配给此变量，则必须在调用子例程时将!MYSTRING! 括在双引号中以将批处理文件的所有参数作为 1 个参数传递给子例程。

FOR 命令可用于将分配给 MYSTRING 的字符串拆分为命令 (ping) 及其参数（使用重定向器运算符）。

---

更新（问题更新后）：

根本不清楚任务是什么。 This batch code 旨在将第一个参数传递给批处理文件，这就是 #%1# 在第二个内部 FOR 循环中的原因。这正是批处理代码所做的，尽管它包含一个对结果没有影响的小错误。

set "prompt=" 无效，因为不可能将提示文本更改为空。所以文件params.txt 仍然包含提示文本。更好的是使用prompt $_ 或set "prompt=$_"，它将提示文本定义为仅回车+换行，因此在读取生成的文件@987654340 时只生成一个被稍后使用的命令FOR忽略的空行@。在第一个外部 FOR 循环之后，使用 endlocal 恢复之前的提示定义。

Paul，您刚刚将(1) 替换为('%*')，其效果是，对于传递给批处理文件的每个参数，第一个也是唯一一个参数被写入文本文件params.txt，然后读取在几次。只需查看params.txt 以查看在使用各种参数运行批处理文件后它包含的内容。这当然不是很有用。

这里是修改后的批处理代码，输出传递给批处理文件的所有参数。

@echo off
setlocal DisableDelayedExpansion
del param.txt 2>nul
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (%*) do rem * #%%~b#
    @echo off
) > param.txt
endlocal

setlocal EnableDelayedExpansion
set "ParaNumber=1"
set "AllParameters="
for /F "delims=" %%L in (param.txt) do (
    set "Parameter=%%L"
    set "Parameter=!Parameter:*#=!"
    set "Parameter=!Parameter:~0,-2!"
    set "AllParameters=!AllParameters! !Parameter!"
    echo Parameter !ParaNumber! = !Parameter!
    set /A ParaNumber+=1
)
set "AllParameters=!AllParameters:~1!"
echo All parameters: !AllParameters!
endlocal

用下面三个字符串依次调用批处理文件3次

"# % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^ "
"ping -n 4 -w 1 127.0.0.1 >NUL"
ping -n 4 -w 1 127.0.0.1

产生以下三个输出

Parameter 1 = # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^
All parameters: # % $ ` ' ( ) < << >> > >NUL && & || | { } \ / - + = , . : ; ^

Parameter 1 = ping -n 4 -w 1 127.0.0.1 >NUL
All parameters: ping -n 4 -w 1 127.0.0.1 >NUL

Parameter 1 = ping
Parameter 2 = -n
Parameter 3 = 4
Parameter 4 = -w
Parameter 5 = 1
Parameter 6 = 127.0.0.1
All parameters: ping -n 4 -w 1 127.0.0.1 >NUL

现在使用"*" 调用批处理文件会导致将当前目录中的所有非隐藏文件列为参数1 到n。因此，修改后的批处理文件版本不适用于有效文件名模式的参数。