如何使用 fluent api 和 Entity Framework 和 Code First 指定小数精度？

Question

我有一个用于测试 Fluent API 的解决方案。当尝试设置小数的精度时，只有当我将调用放入 OnModelCreating 方法并通过实体时，数据库才会正确更新。尝试使用 EntityTypeConfiguration 类时，数据库拒绝更新。 MilesFromNearestAirport 是有问题的财产。

住宿模式

Public Class Lodging
    Public Property LodgingId As Integer
    Public Property MilesFromNearestAirport As Decimal
End Class

DBContext 类

    Public Class BreakAwayContext
        Inherits DbContext

        Public Property Lodgings As DbSet(Of Lodging)
        Protected Overrides Sub OnModelCreating(modelBuilder As DbModelBuilder)
            modelBuilder.Configurations.Add(New LodgingConfiguration)
        End Sub
    End Class

住宿配置类

Public Class LodgingConfiguration
    Inherits EntityTypeConfiguration(Of Lodging)

    Public Sub LodgingConfiguration()
        [Property](Function(l) l.MilesFromNearestAirport).HasPrecision(8, 1)
    End Sub

End Class

我正在使用控制台应用程序进行测试。这是Sub Main ()

Sub Main()
    Database.SetInitializer(New DropCreateDatabaseAlways(Of BreakAwayContext))
End Sub

如您所见，每次运行时我都会删除并重新创建数据库，而不管模型是否发生变化。如果我把小数精度配置设置在 OnModelCreating 方法中，一切都很好。

    Protected Overrides Sub OnModelCreating(modelBuilder As DbModelBuilder)
        modelBuilder.Entity(Of Lodging).Property(Function(l) l.MilesFromNearestAirport).HasPrecision(8, 1)
    End Sub

使用 EntityTypeConfiguration 是否有任何限制，或者是否有人对我可能出错的地方有任何建议？我打算发布生成的数据库表的图片，但由于我的声誉点，我无法发布图片。如果您想了解更多关于类、解决方案、环境等的信息，请告诉我。我正在使用 EF6、.NET4、VB.NET 和 SQL Server Express。

Answer 1

好的，我发现了这个问题，以防其他人遇到这个问题。我正在处理 C# 示例并使用在线转换器将它们转换为 VB。我对 C# 不是很熟悉，并且错误地转换了代码。

这一行Public Sub LodgingConfiguration()

Public Class LodgingConfiguration
    Inherits EntityTypeConfiguration(Of Lodging)

    Public Sub LodgingConfiguration()
        [Property](Function(l) l.MilesFromNearestAirport).HasPrecision(8, 1)
    End Sub

End Class

应该是Public Sub New()

Public Class LodgingConfiguration
    Inherits EntityTypeConfiguration(Of Lodging)

    Public Sub New()
        [Property](Function(l) l.MilesFromNearestAirport).HasPrecision(8, 1)
    End Sub

End Class

这似乎解决了所有问题。感谢@Slauma 看一看！