用于列出名称的 VBA 宏代码

Question

我有一个 Excel 工作表，其中名称为一列，工作时间为下一列的值。

我想将值大于 40 的名称复制到新工作表中，并且列中没有任何空格。新的工作表应该有名字和工作时间；值列中的任何文本都应被忽略。

Sub CopyCells()
    Dim sh1 As Worksheet, sh2 As Worksheet 
    Dim j As Long, i As Long, lastrow1 As Long 

    Set sh1 = Worksheets("Sheet1") 
    Set sh2 = Worksheets("Sheet2") 
    lastrow1 = sh1.Cells(Rows.Count, "F").End(xlUp).Row 

    For i = 1 To lastrow1 
        If sh1.Cells(i, "F").Value > 20 Then 
            sh2.Range("A" & i).Value = sh1.Cells(i, "F").Value 
        End If 
    Next i 
End Sub

Answer 1

我建议使用AutoFilter 进行复制和粘贴，因为它比循环更快。请参阅下面的示例。

我的假设

1. 原始数据在工作表 1 中，如下图所示
2. 您希望工作表 2 中的输出如下图所示

代码

我已经对代码进行了注释，以便您理解它不会有问题。

Option Explicit

Sub Sample()
    Dim wsI As Worksheet, wsO As Worksheet
    Dim lRow As Long
    
    '~~> Set the input sheet
    Set wsI = Sheets("Sheet1"): Set wsO = Sheets("Sheet2")
    
    '~~> Clear Sheet 2 for output
    wsO.Cells.ClearContents
    
    With wsI
        '~~> Remove any existing filter
        .AutoFilterMode = False
        
        '~~> Find last row in Sheet1
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row
        
        '~~> Filter Col B for values > 40
        With .Range("A1:B" & lRow)
            .AutoFilter Field:=2, Criteria1:=">40"
            '~~> Copy the filtered range to Sheet2
            .SpecialCells(xlCellTypeVisible).Copy wsO.Range("A1")
        End With
        
        '~~> Remove any existing filter
        .AutoFilterMode = False
    End With
    
    '~~> Inform user
    MsgBox "Done"
End Sub

快照

Answer 2

试试犀牛

Sub CopyCells()
    Dim sh1 As Worksheet, sh2 As Worksheet
    Dim j As Long, i As Long, lastrow1 As Long
    Set sh1 = Worksheets("Sheet1")
    Set sh2 = Worksheets("Sheet2")
    lastrow1 = sh1.Cells(Rows.Count, "F").End(xlUp).Row
    j = 1
    For i = 1 To lastrow1
        If Val(sh1.Cells(i, "F").Value) > 20 Then
            sh2.Range("A" & j).Value = sh1.Cells(i, "F").Value
            j = j + 1
        End If
    Next i
End Sub