对于命令帮助 - 嵌套命令

Question

我创建了以下简单的批处理文件....我在这里尝试完成的是使用远程命令（RCMD 实用程序）连接到（clusters.txt）中定义的服务器列表并删除列表视频文件在（assets.txt）中定义......我想删除每台服务器上的这些资产。这个批处理文件可以工作，但是它必须连接和断开连接才能删除每一个资产，而这正是我想要避免的。我希望能够连接到 1 台服务器并使用 scp del cmd 删除我的资产列表 %%B，然后断开与该服务器的连接并转到列表 %%A 上的下一个服务器，并从那里删除所有资产连接，而不必连接和断开 200 次。

@echo off

FOR /F "tokens=*" %%A IN (clusters.txt) DO FOR /F "tokens=*" %%B in (assets.txt) DO rcmd \\%%A \vstrmkit\scp del %%B

这是文件列表的样子：

11E8A51A*
11E8A51D*
11E8A614*
11E88E4E*
11E88E4C*

服务器列表只是带有字母和数字的计算机主机名：

SEA88630-N0

任何帮助将不胜感激。

Answer 1

在不知道操作系统的服务器和客户端版本的情况下，可能会有某种命令行限制。但是，让我们试试

@echo off

    rem prepare environment
    setlocal enableextensions enabledelayedexpansion

    rem Define the command that will be executed for each element
    set "command=echo \vstrmkit\scp del"

    rem Prepare the command for the list of files into a environment variable
    set "command=set c=%command% "
    for /f "tokens=*" %%f in (assets.txt) do set "command=!command!/@c@%%~f"

    rem Adjust the command variable to generate a valid concatenation of commands
    set "command=%command:/=&%"

    rem Connect to each of the servers sending the generated command
    rem In the last step, change the @ with ! to generate on remote, when
    rem delayed expansion is applied, the correct final command to execute
    setlocal disabledelayedexpansion    
    for /f "tokens=*" %%a in (clusters.txt) do rcmd \\%%a cmd.exe /v:on /c "%command:@=!%"

请注意，在定义主命令的那一行，插入了一个echo 用于测试。如果一切正常，请删除 echo 以使其正常工作。

已编辑 - 选项编号 2

引号似乎有问题。前面的代码在我的系统中有效，但在 OP 中无效。让我们试试另一个。它也适用于我的系统。

@echo off

    rem prepare environment
    setlocal enableextensions disabledelayedexpansion

    rem Define the command that will be executed for each element
    set "command=echo \vstrmkit\scp del"

    rem Define a temporary file to contain commands to process
    set "tempFile=%temp%\%~nx0.tmp"

    rem Generate the content of the temp file with the list of commands
    rem to execute for each server
    (
        for /f "tokens=*" %%f in (assets.txt) do echo %command% %%f
        echo exit 
    ) > "%tempFile%"

    rem Connect to each of the servers sending the generated command list
    for /f "tokens=*" %%a in (clusters.txt) do (
        rcmd \\%%a < "%tempFile%"
    )

    del /f /q "%tempFile%" > nul 2>nul

    endlocal

Answer 2

@ECHO OFF
SETLOCAL

SET "filelist="
FOR /f "delims=" %%A IN (assets.txt) DO CALL SET filelist=%%filelist%% %%A
FOR /F "tokens=*" %%A IN (clusters.txt) DO echo rcmd \\%%A \vstrmkit\scp del %filelist%
GOTO :EOF

所需的命令只是ECHOed 用于测试目的。确认命令正确后，将ECHO rcmd改为rcmd执行删除

---

如果命令不能接受多个参数的可能解决方案：

创建一个名为delasset.bat 的批处理文件并将其复制到每台目标机器上的\vstrmkit 或每台机器的path 上的某个其他目录中（例如c:\windows 或c:\windows\system32）

delasset.bat 应该包含

@ECHO OFF
ECHO DEL %*

（同样，我只是 ECHOed DEL - 您需要在验证激活后删除 echo）

然后将...rcmd \\%%A \vstrmkit\scp del %filelist%改为...rcmd \\%%A \vstrmkit\scp DELASSET %filelist%

（不区分大小写；我已将其大写以强调）

---

另一种可能的方式：

@ECHO OFF
SETLOCAL

SET "filelist="
FOR /f "delims=" %%A IN (assets.txt) DO CALL SET filelist=%%filelist%%:%%A
SET filelist=%filelist:~1%
FOR /F "tokens=*" %%A IN (clusters.txt) DO echo rcmd \\%%A \vstrmkit\scp del %filelist::=^&\vstrmkit\scp del %
GOTO :EOF

应该生成（例如）

rcmd \\SEA88630-N0 \vstrmkit\scp del 11E8A51A*&\vstrmkit\scp del 11E8A51D*&\vstrmkit\scp del 11E8A614*&\vstrmkit\scp del 11E88E4E*&\vstrmkit\scp del 11E88E4C*

请注意，filelist 现在使用冒号分隔项目。冒号不能是文件名的一部分。第一个字符（这将是一个冒号，因为filelist 附加了:filenamefromfile）然后被剥离（请参阅子字符串文档提示中的set/?）

%filelist::=^&\vstrmkit\scp del % 中的象形文字意思是'带有文件列表，用字符串&\vstrmkit\scp del 替换（第一个:）[第一个: 和= 之间的字符-恰好是一个冒号] （即= 和结束% 之间的所有字符 - 附加修改是因为& 是cmd 的特殊字符（这意味着'在& 之前做事，然后在之后做事' ) & 需要用插入符号 (^) “转义”，表示“这是我想用作普通字符的特殊字符”。

将echo 牢牢固定在原位将使您能够准确地看到应该交付的内容。可悲的是，我不知道它是否正确......

Answer 3

这样的事情应该会有所帮助。 我现在不知道你在文件名后面有一个*，但它必须被删除 剧本。或者那是.* ???

编辑：如果您有各种具有相同名称的文件和各种（“未知”）扩展名，那么您必须使用新的 FOR 循环测试扩展名：

@echo off
setlocal EnableDelayedExpansion

FOR /F "tokens=*" %%A IN ('type clusters.txt') DO (
            FOR /F "tokens=*" %%B in ('type assets.txt') DO (
                     set $asset=%%B
                     rcmd.exe \\%%A \vstrmkit\scp del !$asset:~0,-1!.*))