在 BAT 中提取文本文件的一部分

Question

我每天都在捕获一个 m3U 文件，但希望用我需要的几个频道将其中的一部分解析为另一个文件。

例如，我已将我的 m3U 重命名为 Test.txt 文件，该文件具有以下虚构结构：

#EXTINF:0,ABC  
#live link 1
#EXTINF:0,XYZ   
#live link 2
#EXTINF:0,UVW  
#live link 3

我只想捕获说从“#EXTINF:0,XYZ”开始的行，然后说它下面的行以如下所示的 Output.txt 结尾：

#EXTINF:0,XYZ   
#live link 2

我知道需要使用 For 循环，但我在这方面有点菜鸟。

Answer 1

将此代码放入文件filter.cmd。

@echo off
set INPUT=%1&set MATCH=%2& set MATCHED=0
for /f "delims=" %%a in (%INPUT%) do call :line "%%~a"
goto :eof
:line
set EXT=&TITLE=&
for /f "tokens=1 delims=:" %%a in ("%~1") do set EXT=%%~a
for /f "tokens=1,2,* delims=:," %%a in ("%~1") do set TITLE=%%~c
if "%EXT%" == "#EXTM3U" echo %~1
if "%EXT%" == "#EXTINF" (
  set MATCHED=0
  echo %TITLE%| findstr /l %MATCH% >nul  && set MATCHED=1
)
if %MATCHED%==1 echo %~1

使用示例：

filter.cmd input_file.m3u XYZ > output_file.m3u

这里有一些解释：
每个输入行都使用 for /f 与标记和分隔符进行拆分。 如果该行以#EXTINF 开头并且其余包含要匹配的字符串（第二个参数），则设置 MATCHED。 如果设置了 MATCHED，则输出这些行直到下一个 #EXTINF。

Answer 2

我会这样做，假设 .m3u 文件在 #EXTINF 前面的行中不包含尾随空格，就像您的示例数据一样：

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "FILE=%~1"
set "HEADER=#EXTM3U"
set "PREFIX=#EXTINF"
set "MATCH=%~2"

set "FLAG="
for /F usebackq^ delims^=^ eol^= %%L in ("%FILE%") do (
    if defined FLAG (
        echo(%%L
        set "FLAG="
    )
    for /F "delims=:" %%P in ("%%L") do (
        if "%%P"=="%HEADER%" (
            echo(%%L
        ) else if "%%P"=="%PREFIX%" (
            set "LINE=%%L"
            setlocal EnableDelayedExpansion
            if /I "!LINE:*,=!"=="!MATCH!" (
                echo(!LINE!
                endlocal
                set "FLAG=#"
            ) else endlocal
        )
    )
)

endlocal
exit /B

这样调用脚本，假设保存为extract-entry.bat:

extract-entry.bat "input_file.m3u" "XYZ" > "output_file.m3u"

脚本逐行遍历给定的.m3u 文件。如果设置了变量FLAG，则返回未编辑的当前行并重置变量FLAG，而开头并非如此。

然后它寻找#EXTINF。如果找到（例如，#EXTINF:0,XYZ），则将逗号后面的字符串（XYZ）与给定的搜索字符串进行比较。如果匹配，则输出当前行并设置FLAG 变量，以便也获得以下行。

标题行#EXTM3U 总是输出。

切换delayed expansion 使该脚本对所有对命令解释器具有特殊意义的字符具有鲁棒性，而不会丢失它们。