使 for 循环一次读取 2 行文本文件

Question

我有一组文件夹，每个文件夹都有一个同名的 txt 文件。他们的路径是

C:\Test\Salford_xxx\MenuSettings.txt
C:\Test\Salford_xxx\MenuSettings.txt
C:\Test\Salford_xxx\MenuSettings.txt

其中 xxx 是一个随机的 3 位数字。我希望使用名为 input.txt 的文本文件更改每个文件的第一行，该文本文件具有替换每个文件第一行的路径和行。看起来像这样。

C:\TEST\SALFORD_001\MENUSETTINGS.TXT
AppName: "This needs replacing 1"
C:\TEST\SALFORD_011\MENUSETTINGS.TXT
AppName: "This needs replacing 2"
C:\TEST\SALFORD_345\MENUSETTINGS.TXT
AppName: "This needs replacing  3"
C:\TEST\SALFORD_761\MENUSETTINGS.TXT
AppName: "This needs replacing 4"
C:\TEST\SALFORD_768\MENUSETTINGS.TXT
AppName: "This needs replacing 5"
C:\TEST\SALFORD_999\MENUSETTINGS.TXT
AppName: "This needs replacing 6"

我编写了一个 for 循环，将路径和替换放入变量中，它有效：

for /F "delims=" %%a in ('findstr /R /I "Salford" Input.txt') do (set "FilePath=%%a" echo %FilePath%)
for /F "delims=" %%b in ('findstr /R /I "AppName" Input.txt') do (set "NewName=%%b" echo %NewName%)

AppName 是始终位于第一行的单词，因此用于搜索。 这是用于替换每个文件的行的脚本。

set "search=Appname"
set "replace=%NewName%"
set "newfile=NewOutput.txt"

(for /f "delims=" %%i in (%FilePath%) do (
set "line=%%i"
    setlocal enabledelayedexpansion
    set "line=!line:%search%=%replace%!"
    echo(!line!
    endlocal
))>"%newfile%"
move "%newfile%" "%FilePath%"

但是，循环继续到 Salford_999 文件夹中的最后一项，并仅编辑该文件。我怎样才能让它读取 input.txt 的前两行，进行替换，然后循环到接下来的两行等等？

谢谢

Answer 1

我不明白您的代码如何使用您的规范。例如，您的“将路径放入变量中的 for 循环”将所有路径 分配给同一个变量，因此当 for 结束时，该变量具有 最后一个值。另外，我不明白“AppName”字符串文字在第二个中用于findstr 时是从哪里获取的。最后，如果有一个文件在 input.txt 文件中没有对应的行怎么办？

另一种方法是将 input.txt 文件处理为一系列奇数/偶数行，然后处理以奇数行描述的每个文件；这可能会导致更简单的解决方案：

@echo off
setlocal EnableDelayedExpansion

rem Process odd and even lines from input.txt file:
set "FilePath="
for /F "delims=" %%a in (input.txt) do (
   if not defined FilePath (  rem Odd line...
      rem Assign each odd line to "FilePath" variable
      set "FilePath=%%a"
   ) else (  rem Even line...
      rem Process this file, if it exists
      if exist "!FilePath!" (
         rem Block to enclose output to new file
         > newfile (
            rem The first line in new file is this even line in input.txt file
            echo %%a
            rem Copy all lines from this file, excepting the first one
            more +1 "!FilePath!"
         )
         move /Y newfile "!FilePath!"
      )
      set "FilePath="
   )
)