使用 wmic 进行批处理循环

Question

下面的输出

wmic logicaldisk get providername /value

在我正在使用的计算机上使用 cmd（用户权限有限）是：

ProviderName=


ProviderName=


ProviderName=\\xxx-SN-NA01\Users2\N\ni


ProviderName=\\xxx-sn-na01\Software_Ca


ProviderName=\\xxx-sn-na01\TSO

我正在尝试访问存储在名为 %drives_paths_wmic% 的变量中的以下内容：

\\xxx-SN-NA01\Users2\N\ni \\xxx-sn-na01\Software_Ca \\xxx-sn-na01\TSO

然后将 this 的内容传输到变量 %file% 中。

我目前拥有的批处理代码是：

@echo off
setlocal enabledelayedexpansion 
for /F "tokens=2 delims='='" %%A in ('wmic logicaldisk get providername /value') do (
  echo %%A >> %drive_paths_Wmic%
)
echo %drive_paths_Wmic%
echo %drive_paths_Wmic% >> %file%

编辑：问题是 %drive_paths_Wmic% 变量中没有存储任何内容。

由于批处理文件需要在 Windows 7 和 XP 计算机上运行，​​因此我无法使用 PowerShell。 请建议更改批处理代码以执行此操作？

Answer 1

您没有指定问题。然而：

'1'。 delims==语法

for /F "tokens=2 delims==" %%A in ('wmic logicaldisk get providername /value') do @echo %%A

上述命令的输出是否正确？我不敢说，因为

'2'。 wmic 的所有输出都是 Unicode。要转换为 ASCII，请尝试下一个代码 sn-p：

wmic logicaldisk get providername /value >somename.txt
for /F "tokens=2 delims==" %%A in ('type somename.txt') do @echo %%A

'3'。结果到变量：

set "file=" 
rem variable initialized now
rem ... some code ...
for /F "tokens=2 delims==" %%A in ('type somename.txt') do set file=!file! %%A
rem ... some code ...
echo !file!
echo %file%

也可以是set "file=!file! %%A"

整批：

@ECHO OFF >NUL
@SETLOCAL enableextensions enabledelayedexpansion
set "drive_paths_Wmic=" 
rem variable initialized now
rem ... some code ...
wmic logicaldisk get providername /value >somename.txt
for /F "tokens=2 delims==" %%A in ('type somename.txt') do (
  set drive_paths_Wmic=!drive_paths_Wmic! %%A
  @rem ... some code ...
  )
echo !drive_paths_Wmic!
echo %drive_paths_Wmic%
Endlocal
goto :eof

输出（在我的电脑上）：

C:\bat>fivmic
 \\pc1870a\ttemp \\PC1870A\Install
 \\pc1870a\ttemp \\PC1870A\Install

输出（与echo ON 部分）

C:\bat>fivmic
C:\bat>wmic logicaldisk get providername /value  1>somename.txt
C:\bat>for /F "tokens=2 delims==" %A in ('type somename.txt') do set drive_paths_Wmic=!drive_paths_Wmic! %A
C:\bat>set drive_paths_Wmic=!drive_paths_Wmic! \\pc1870a\ttemp
C:\bat>set drive_paths_Wmic=!drive_paths_Wmic! \\PC1870A\Install
C:\bat>rem ... some code ...
C:\bat>echo !drive_paths_Wmic!
 \\pc1870a\ttemp \\PC1870A\Install
C:\bat>echo  \\pc1870a\ttemp \\PC1870A\Install
 \\pc1870a\ttemp \\PC1870A\Install

如果%file% 变量包含有效的文件名，那么您可以将回显重定向到该文件，例如echo bubu >> anyname.txt 将文本 bubu（在新行上）附加到文件 anyname.txt。在您的脚本中：

set file="anyname.txt"
echo %drive_paths_Wmic% >> %file%