Windows批处理文件数学怪异

Question

为什么这不起作用？

@echo off

for /l %%i in (0, 1, 100) do (
    for /l %%j in (0, 1, 10) do (
        set /a curr=%%i*10 + %%j
        echo %curr%
    )
    echo "-----------------------------"
)

这是我从中得到的输出：

1010
1010
1010
1010
1010
1010
1010
1010
1010
1010
1010
"----------------------------"
1010
1010
1010
1010
1010
1010
1010
1010
...

它似乎在执行之前预先计算了数学，所以当它最终执行时，%curr% 已经是 1010。我该如何防止它这样做？我试图得到这样的输出：

0
1
2
3
4
5
6
7
8
9
10
"----------------------------"
11
12
...

提前致谢

Johannes Rössel 的回答（供以后可能会寻找的人）：

@echo off
setlocal enabledelayedexpansion enableextensions

for /l %%i in (0, 1, 100) do (
    for /l %%j in (0, 1, 10) do (
        set /a curr=%%i*10+%%j
        echo !curr!
    )
    echo "-----------------------------"
)

Answer 1

通过在循环之前添加以下行来使用延迟扩展：

setlocal enabledelayedexpansion enableextensions

然后使用环境变量为!curr!，而不是%curr%。

您正在更改块内环境变量的内容并且在同一块中再次使用更改后的内容。如果没有延迟扩展，这是行不通的。原因是cmd 在解析命令时扩展了%foo% 之类的变量，而if 或for 之类的命令也包括可能跟随的块。延迟扩展会导致在执行您想要的命令之前立即评估变量。

help set 包含对没有延迟扩展的问题的描述，并且可以使用它。