for循环中的if语句不起作用

Question

所以我正在编写一个脚本来判断一个动作是否已经被执行。我从一个包含 0 的 2x2 数组开始。我想在四个元素中随机存储三个 1，如果元素已经存储了 1，则 echo 重复以通知用户。这是我到目前为止的代码，即使多次选择相同的元素，它也不会回显重复。

@echo off
setlocal EnableDelayedExpansion
::::::::::::::::::::::::::::::::::::::::::::Creating a 2x2 zero array
for /l %%y in (0,1,1) do (
    for /l %%x in (0,1,1) do (
        set map[%%x][%%y]=0
    )
)
::::::::::::::::::::::::::::::::::::::::::::Putting 1s in elements randomly
for /l %%x in (1,1,3) do (
    set /a j=!Random!%%2
    set /a i=!Random!%%2
    if !map[%i%][%j%]! EQU 0 (set map[!i!][!j!]=1) else (echo Repeated)
)
::::::::::::::::::::::::::::::::::::::::::::Result
echo !map[0][0]!!map[1][0]!
echo !map[0][1]!!map[1][1]!
echo.
pause

我在网上阅读了一些相关的内容，并且很确定它与“setlocal EnableDelayedExpansion”有关，但我不知道该怎么做。提前致谢。

Answer 1

for /l %%x in (1,1,3) do (
    set /a j=!Random!%%2
    set /a i=!Random!%%2
    SET /a s=map[!i!][!j!]
    if !s! EQU 0 (set map[!i!][!j!]=1) else (echo Repeated)
)

在您的代码中，%i% 和 %j% 都将被解析为 nothing，因为在遇到 for 时既没有设置 i 也没有设置 j - %var% 表示“当块开始时var的值”因此你的if被解析为if !map[][]! EQU 0 ... - map[][]是一个有效的varname。

要访问变量的值随着块的操作而变化（即“运行时”值），您需要在操作中使用!var! 和delayed expansion。这将产生（理论上）

if !map[!i!][!j!]! EQU 0 (set map[!i!][!j!]=1) else (echo Repeated)

但是这行不通，因为cmd 无法解析哪些! 对首先解析（它将选择!map[!、!][! 和@987654339 @reulting in if ij equ 0 ... 这显然总是会失败）

所以 - 我选择将 s 设置为从 map 提取的值，然后测试 。