如果已执行，如何不在循环内输入 if 语句

Question

我有一个 for 循环，里面有 if 语句。

在我的 Excel 中，我有一个包含每个值一次的列表。一旦我发现它，我什至不希望代码检查条件，我希望它在每次执行循环时完全跳过这部分 if 语句，这可能吗？

这是我的代码和列表：

循环的第一次迭代会发现“c”是值，所以它会在里面做些什么（xc = i）

我什至不希望代码再次检查“ElseIf Cells(1, i) = "c"，如下图，这可能吗？

编码为文本：

Sub test()

Dim i, xa, xb, xc As Integer

For i = 1 To 5

    If Cells(i, 1) = "a" Then
      xa = i
    ElseIf Cells(i, 1) = "b" Then
      xb = i
    ElseIf Cells(i, 1) = "c" Then
      xc = i
    End If

Next i

End Sub

Answer 1

我对您的需求的最初解释是“如果代码再次点击 'c'，就不要采取行动”。

为此，您可以按如下方式修改逻辑：

ElseIf (xc = 0) And (Cells(i, 1) = "c") Then

这样，一旦设置了xc，第一个布尔表达式就会为False，并且不会再次满足整体条件。正如@TimWilliams 所提到的，与其他具有短路选项的语言不同，VBA 仍将评估第二个布尔表达式。 @Gene 的回答描述了一种解决方法。通常，为了获得更好的性能，您会先评估简单的条件，然后再求助于代价高昂的条件。

补充说明

在 VBA 中，您必须为每个变量指定一个类型。在您的Dim 行中，只有 xc 是 Integer，而其他变量是 Variants。

一个不合格的Cells() 调用在当前活动的工作表上运行，这可能不是预期的。建议：使用工作表的 CodeName 限定 Cells()。 CodeName 是您在工作表的(Name) 属性下看到或指定的内容，如从Visual Basic 编辑器中看到的那样。例如，如果(Name) 是Sheet1，则使用Sheet1.Cells()。这仅在代码与Sheet1 位于同一工作簿中时才有效。如果代码在工作表本身后面，您甚至可以使用Me.Cells()。

当像您的代码那样处理单元格值时，VBA （默默地）很好并且理解，在 Range 类的众多属性中，Value 是您感兴趣的。这是更好的做法，但是，要显式声明目标属性，例如在Sheet1.Cells(i, j).Value 中。

编辑

知道值将是不同的并且大约有 60 个，我建议您只需使用字典，如下所示，一次性获取每个值的行，而无需级联 Ifs：

Option Explicit

Sub test()
    Dim i As Integer
    Dim dict As Object 'Scripting.Dictionary

    Set dict = CreateObject("Scripting.Dictionary")

    For i = 1 To 5
        dict(Cells(i, 1).Value) = i
    Next

    Debug.Print dict("a") '4
    Debug.Print dict("b") '2
    Debug.Print dict("c") '1
    'Etc.
End Sub

Answer 2

如果我理解你的问题，你可以试试这个代码：

Sub test()
Dim i, xa, xb, xc As Integer
Dim a, b, c As Boolean

a = False 
b = False
c = False

For i = 1 To 5

    If Cells(i, 1) = "a" And a <> True Then

        xa = i
        a = True
    ElseIf Cells(i, 1) = "b" And b <> True Then

        xb = i
        b = True
    ElseIf Cells(i, 1) = "c" And c <> True Then

        xc = 1
        c = True

    End If

Next i
End Sub

布尔变量设置为真，例如仅当单元格(i,1)="a" 和下一个 "a" 值被跳过...

希望对你有帮助

Answer 3

我只是想“修改”费迪南多的代码，这样它就更“可读”了，我想。此版本与费迪南多或 Excelosaurus 之间的主要（实质性）区别在于，一旦检测到值，甚至不测试单元格。请记住，问题是：我不希望代码再次检查“ElseIf Cells(1, i) = "c"...所以，这个版本就是这样做的。

Sub test()
Dim i As Integer, xa As Integer, xb As Integer, xc As Integer
Dim aFound As Boolean, bFound As Boolean, cFound As Boolean
Dim r As Range

For i = 1 To 5
    Set r = Cells(i, 1)
    If Not aFound Then
        If r = "a" Then xa = i: aFound = True
    ElseIf Not bFound Then
        If r = "b" Then xb = i: bFound = True
    ElseIf Not cFound Then
        If r = "c" Then xc = i: cFound = True
    End If
Next i
End Sub

Answer 4

我不喜欢 60 个 ElseIfs 的想法。请检查下面的代码。为了对其进行测试，请创建一个名为“TestSheet”的工作表并将 A1:A5 输入到单元格 H2:H6。

Sub TestSpike()
    ' 06 Jan 2019

    Dim Rng As Range
    Dim Items As Variant
    Dim Spike As String
    Dim Tmp As String
    Dim i As Integer
    Dim R As Long

    Items = Split("c|b|0|a|1", "|")
    With Worksheets("TestSheet").Columns("H")
        For R = 2 To 6
            Tmp = CStr(.Cells(R).Value)
            If InStr(1, Spike, Tmp, vbTextCompare) = 0 Then
                Spike = Spike & "|" & Tmp

                On Error Resume Next
                i = Application.WorksheetFunction.Match(Tmp, Items, 0)
                If Err Then
                    MsgBox Tmp & " wasn't found in Array"
                Else
                    MsgBox "i = " & i & " = Item " & Tmp
                End If
            End If
        Next R
    End With
End Sub

代码有一个“尖峰”。首先根据 Spike 检查每个项目。如果发现，则不进行进一步的测试。否则，它会被添加到 Spike。 新项目在添加到 Spike 后，将根据包含 60 个元素的数组“Items”进行检查，由 Chr(124) 分隔，因此，Split("c|b|0|a|1", "|" ）。我使用工作表函数 MATCH 来查找数组中的项目。结果是索引号（或错误，如果未找到）。您可以在 Select Case 语句中使用此索引号来处理与其他项不同的每个项目，这与您现在在 If 语句返回 True 时处理它的方式基本相同。 您可能会发现对这种设置有用的一个想法是使用 Match 函数中的索引从另一个数组返回一个值。例如，另一个数组可能包含函数名称，并且您使用 Application.Run 为每个项目调用不同的函数。这比检查 60 多个 Select Case 语句的运行速度要快得多。