批处理 IF 命令未运行

Question

我试图在一些文件中获取几行并将它们存储在变量中（line3 和 line4）。
这是代码：

setlocal EnableDelayedExpansion

for /f "tokens=*" %%a in ('dir *.md /b /o:-n /a:-d') do (
call :getLines "%%a"
)

pause
exit

:getLines
set /A cnt=2
for /f "skip=4 tokens=*" %%b in (%1) do (
set /A cnt+=1
set "line!cnt!=%%b"
if !cnt! == 4 (
    set "filename=%~n1"
    set "blogdate=!filename:~0,10!"
    set "blogtitle=!filename:~11!"
    echo hello
    echo !line3!
    echo !line4!
    echo !filename!
    echo !blogdate!
    echo !blogtitle!
)
)
goto :eof

以上内容甚至不会回显hello。我看不出有什么问题。
这是每个文件的样子：

# Title

*2015-11-17*

Tags: word1 word2

First Sentence is here.

文件名如下所示：

2015-11-17-title.md

Answer 1

您通过引号传递给调用，因此您应该先去掉它（或使用usebackq）。
另外，在您进行测试时，请不要使用exit。
试试这个，看看它是否有效：
（格式化使结构更清晰，请尝试评论@echo off以获取更多详细信息。）

@echo off
setlocal EnableDelayedExpansion

for /f "tokens=*" %%a in ('dir *.md /b /o:-n /a:-d') do (
    call :getLines "%%a"
)

pause
::exit
goto :eof

:getLines
set /A cnt=2
for /f "usebackq skip=4 tokens=*" %%b in (%1) do (
    set /A cnt+=1
    set "line!cnt!=%%b"
    if !cnt! == 4 (
        set "filename=%~n1"
        set "blogdate=!filename:~0,10!"
        set "blogtitle=!filename:~11!"
        echo hello
        echo !line3!
        echo !line4!
        echo !filename!
        echo !blogdate!
        echo !blogtitle!
        goto :eof
    )
)
goto :eof

for 会将带引号的输入作为字符串而不是文件。
%~1 将删除 %1 的引号。
详情请查看for /? 和call /?。