For 循环内的 CMD Setlocal EnableDelayedExpansion 无法正常工作

Question

我想创建一个批处理文件函数来查看服务器，看看我是否需要更新任何程序。我现在设置的方式在

for /l ...

我面临的问题是你需要在循环内部使用 !var!获取更新后的变量值。如果你使用 goto 函数作为 /l 的 sudo 绕过它，它可以工作

以下是无法正常工作的代码行

setlocal enabledelayedexpansion
...

Set LocalL1=Example1.exe
Set /a LocalL1.Byte=1234
...

Set Servr1L=Example2.exe
Set /a LocalL1.Byte=1234
...

FOR /L %%A IN (1,1,%ServrList.Count%) DO (
   Set Temp1=!%LocalL%%%A!
   Set Temp2=!%ServrL%%%A!
   Set Temp1=!!Temp1!.byte!
   Set Temp2=!!Temp2!.byte!
)

实际结果

FOR /L %%A IN (1,1,%ServrList.Count%) DO (
   Set Temp1=Example1.exe
   Set Temp2=Example2.exe
   Set Temp1=Example2.exe.byte
   Set Temp2=Example2.exe.byte
)

我希望它输出什么

FOR /L %%A IN (1,1,%ServrList.Count%) DO (
   Set Temp1=Example1.exe
   Set Temp2=Example2.exe
   Set Temp1=1234
   Set Temp2=1234
)

如果您需要更多代码，请告诉我，但我必须执行“！%LocalL%%%A！”让它工作。在 For /L 之外，它只是不想对每个都进行硬编码

Answer 1

这个批处理代码应该可以工作，虽然不清楚你真正想要什么：

@echo off
setlocal EnableExtensions EnableDelayedExpansion
rem ...

set "LocaleL1=Example1.exe"
set "LocaleL1.Byte=1234"
rem ...

set "ServerL1=Example2.exe"
set "ServerL1.Byte=4321"
rem ...

set "ServerList.Count=1"

for /L %%A in (1,1,%ServerList.Count%) do (
   set "MyLocaleLabel=!LocaleL%%A!"
   set "MyServerLabel=!ServerL%%A!"
   set "MyLocaleByte=!LocaleL%%A.Byte!"
   set "MyServerByte=!ServerL%%A.Byte!"
   set My
   echo/
)

endlocal

Windows 命令解释器首先在命令块循环执行期间用当前循环变量值替换%%A。然后执行 SET 并延迟环境变量扩展，从而将环境变量LocaleL1 的值分配给环境变量MyLocaleLabel，ServerL1 的值分配给MyServerLabel，MyServerLabel 的值到MyLocaleByte，ServerL1.Byte 的值到MyServerByte。

接下来输出名称中以My开头的四个环境变量的值。所以发布的批处理文件在命令提示符窗口中运行时输出：

MyLocaleByte=1234
MyLocaleLabel=Example1.exe
MyServerByte=4321
MyServerLabel=Example2.exe

我更改了所有环境变量名称，因为有问题的原始名称对我来说太混乱了。

提示：不要使用算术表达式为环境变量赋值。环境变量总是字符串类型。

在使用 set /a LocalL1.Byte=1234 的算术表达式时，Windows 命令解释器首先必须将具有十六进制字节 31 32 33 34 00 的字符串转换为具有值 1234 的 32 位有符号整数，并将四个十六进制字节 @ 保存在内存中987654340@（LSB 到 MSB），然后将整数转换回具有五个字节 31 32 33 34 00 的字符串。这没有多大意义，尽管完成得如此之快，以至于没有人会注意到与 set "LocalL1.Byte=1234" 在执行时间上的区别，在该时间上只执行一个简单的字符串副本（如果有的话）。

在命令提示符窗口中进一步运行set /?，并仔细阅读命令SET从第一页到最后一页的输出帮助。环境变量通常可以而且应该在算术表达式中仅通过名称引用，而不使用% 或!，即set /A TCount=TCount + 1 或更短的set /A TCount+=1。帮助解释了为什么这在算术表达式中有效，以及为什么这种语法更好。

要了解所使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• echo /?
• endlocal /?
• for /?
• set /?
• setlocal /?

我建议也阅读一下

• this answer 了解有关命令 SETLOCAL 和 ENDLOCAL 的详细信息。
• 回复Why is no string output with 'echo %var%' after using 'set var = text' on command line?
• 回复Where does GOTO :EOF return to?
• DosTips 论坛主题ECHO. FAILS to give text or blank line - Instead use ECHO/