使用 FOR 循环检查文件是否存在

Question

我正在尝试使用 FOR 循环来创建一个批处理来检查目录中是否存在文件。我正在努力处理文件名中有空格的文件，如果可能的话，我不想使用 .txt 列表。所以这是我迄今为止测试过的。

@echo OFF
:: Variables
set Folder=D:\Test Folder
set Space=File Name With Space.txt
set NoSpace=FileNameWithoutSpace.txt

:: For Loop

FOR %%A in (%Space% %nospace%) do (
if exist "%Folder%\%%A" (
        ECHO %%A exist
        ) else (
            ECHO %%A doesn't exist
            echo. )
)

这是重新打开回显时读取的内容。

(如果存在 "D:\Test Folder\File" (ECHO 文件存在) else (ECHO 文件 不存在回声。 ))

如果我使用这段代码：

@echo OFF    
:: Variables
set Folder=D:\Test Folder
set Space="File Name With Space.txt"
set NoSpace=FileNameWithoutSpace.txt

:: For Loop

FOR %%A in (%Space% %nospace%) do (

if exist "%Folder%\%%A" (
    ECHO %%A exist
    ) else (
        ECHO %%A doesn't exist
        echo. )
)

它将“IF”命令读作：

(如果存在 "D:\Test Folder\"File Name With Space.txt"" (ECHO "File Name With Space.txt" 存在) else (ECHO "File Name With Space.txt" 不存在回声。 ))

我做错了什么？

Answer 1

Aaron，这是你应该使用的语法，（特别注意双引号的位置，" 和元变量修饰符的使用，@987654322 @):

@Echo Off    
Rem Variables
Set "Folder=D:\Test Folder"
Set "Space=File Name With Space.txt"
Set "NoSpace=FileNameWithoutSpace.txt"

Rem For Loop
For %%A In ("%Space%" "%nospace%") Do (
    If Exist "%Folder%\%%~A" (
        Echo %%~A exists
    ) Else (
        Echo %%~A does not exist
        Echo=
    )
)
Pause

Answer 2

你有

set Space=File Name With Space.txt

所以

FOR %%A in (%Space% %nospace%) do (

翻译成

FOR %%A in (File Name With Space.txt FileNameWithoutSpace.txt) do (

搜索以下文件：

File
Name
With
Space.txt
FileNameWithoutSpace.txt

引用你的论点：

FOR %%A in ("%Space%" "%nospace%") do (