仅在 Active Workbook 上进行 Excel 计算，寻找解决方法

Question

当您打开多个 Excel 文件，并且您的 VBA/VSTO 代码调用 Calculate 函数或打开自动计算时，Excel 将痛苦地重新计算所有打开的工作簿，而不仅仅是活动工作簿。

这是一个众所周知且广为人知的问题，已经存在多年，但微软似乎对修复它并不感兴趣。

Calculate only the active workbook before saving

Microsoft Excel wishlist: Workbook level calculation

可笑的是，在 VBA 和 VSTO 中，Microsoft 让我们能够：

• 重新计算特定的工作表
• 重新计算所有打开的工作簿

...但是没有选择只重新计算一个特定的工作簿。

在我工作的金融公司，这是一个大问题。我们的精算师拥有庞大而庞大的 Excel 文件，其中充满了公式，当他们在一个工作簿上单击“计算”或我们在保存文件之前执行计算时，他们必须等待几分钟才能将所有其他打开的 Excel 文件也 计算出来。

有两种解决方法。

你可以像这样运行一些 VBA：

Application.Calculation = xlManual 
For Each sh In ActiveWorkbook.Worksheets 
    sh.Calculate 
Next sh 

..但这不能保证有效。您的“Sheet1”可能包含指向“Sheet2”中单元格的公式，但“Sheet2”中的其他单元格可能依赖于“Sheet1”。因此，计算每个 Worksheet 一次 可能不足以对您的 Workbook 执行完整计算。

或者，您可以在单独的实例中打开每个 Excel 文件（在打开 Excel 图标时按住 ALT）。但是，您将失去完整的 Excel 剪切和粘贴功能，如下所述：

Can't fully cut'n'paste between Excel instances

那么，我的问题是……有没有人找到解决方法来解决这个问题？

我只是想重新计算 Active Excel 工作簿中的单元格。

我想知道是否可以添加一些 VBA 或 VSTO，在我开始对活动工作簿进行计算之前，将所有非活动工作簿设置为“只读”，从而防止其他工作簿能够被重新计算。但这是不可能的。 “Workbook.ReadOnly”只能读取，不能以编程方式设置。

或者可能向Worksheet_Calculate 事件添加一个处理程序，该处理程序检查正在运行的VBA 代码是否属于活动工作簿，如果不属于，它会中止尝试计算...？但是这个事件实际上是在计算完 Worksheet 之后开始的，所以为时已晚。

我们公司不可能是唯一遭受这个问题的公司......

任何建议（升级到 Lotus 1-2-3 除外）？

Answer 1

此方法使用另一个 Excel 实例来避免多个工作簿计算。使用新实例的几行代码取自 this SO question，它涉及类似的主题，您可能会感兴趣。

您必须在特定情况下测试此速度，因为关闭/打开时间可能不会超过避免的计算！

宏步骤

• 将计算设置为手动
• 保存并退出所需的工作簿
• 在新的 Excel 实例中打开它
• 重新计算
• 在 Excel 的原始实例中保存、关闭和重新打开。

运行此脚本的关键点：

• 宏不能存在于要重新计算的工作簿中，因为它在处理过程中被关闭（两次）。它应该放在其他一些“实用程序”工作簿中。

代码 - 详见 cmets

Sub CalculateWorkbook(WB As Workbook)
    ' Store path of given workbook for opening and closing
    Dim filepath As String
    filepath = WB.FullName
    ' Turn off calculation before saving
    Dim currentCalcBeforeSave As Boolean
    currentCalcBeforeSave = Application.CalculateBeforeSave
    Application.CalculateBeforeSave = False
    ' Store current calculation mode / screen update and then set it to manual
    Dim currentCalcMode As Integer, currentScreenUpdate As Integer
    currentCalcMode = Application.Calculation
    currentScreenUpdate = Application.ScreenUpdating
    Application.Calculation = xlCalculationManual
    Application.ScreenUpdating = False
    ' Close and save the given workbook
    WB.Close savechanges:=True
    ' Open a new INSTANCE of Excel - meaning seperate calculation calls
    Dim newExcel As Excel.Application
    Set newExcel = CreateObject("Excel.Application")
    ' Could make it visible so that any problems don't leave it hidden in the background
    ' newExcel.Visible = False
    ' Set the calculation mode to manual in the new instance sothat the workbook isn't calculated on opening.
    ' This can't be done without an existing workbook object.
    Dim tempWB As Workbook
    Set tempWB = newExcel.Workbooks.Add
    newExcel.Calculation = xlCalculationManual
    newExcel.CalculateBeforeSave = False
    ' Open the workbook in the new instance of Excel
    Dim newWB As Workbook
    Set newWB = newExcel.Workbooks.Open(filepath)
    ' Calculate workbook once
    newExcel.Calculate
    ' Close and save the workbook, tempworkbook and quit new instance
    newWB.Close savechanges:=True
    tempWB.Close savechanges:=False
    newExcel.Quit
    ' Re-open in the active instance of Excel
    Application.Workbooks.Open filepath
    ' Reset the application parameters
    Application.CalculateBeforeSave = currentCalcBeforeSave
    Application.ScreenUpdating = currentScreenUpdate
    Application.Calculation = currentCalcMode
End Sub

通过将您希望重新计算的工作簿对象传递给上面的 sub 来调用它（这可以通过按钮等来完成）。

这已经在一个非常简单的示例工作簿上进行了测试，并且这个概念有效。但是，请先在您的工作簿的副本上进行测试，因为它尚未经过全面的健壮性测试，并且没有错误处理。

Answer 2

我在我的 FastExcel 产品中使用的方法包括将所有非活动工作簿中的所有工作表的 WorkSheet.EnableCalculation 设置为 false，并将活动工作簿中的所有工作表设置为 True。

这可行，但缺点是在您更改活动工作簿时使下一个计算成为对新活动工作簿的完整计算：因此需要权衡。

您可以通过从Download 下载 FastExcel 的试用版来尝试在您的情况下试用 FastExcel V3 版本 231.655.789.380 的 15 天全功能试用版

然后使用 FastExcel Calculation Options 并选中 Current Calculation Mode 设置中的 Active Workbook 复选框；

免责声明：我拥有、开发和销售 FastExcel 产品。包含活动工作簿计算代码的 FastExcel 组件是 FastExcel V3 Calc