根据文件名中的日期合并二进制文件

Question

我在一个目录中有多个文件，格式为 L: data_yyyy_mm_dd_ss.info.dat

我正在尝试编写一个批处理脚本，该脚本将要求用户输入开始/结束日期（并假设用户的输入将匹配 yyyy_mm_dd 文件的格式）然后我希望脚本合并所有相关文件。

Ex 文件：data_2013_12_01_32.info.dat； data_2013_12_02_44.info.dat； data_2013_12_03_22.info.dat； data_2013_12_04_33.info.dat；数据_2013_12_05_52.info.dat； data_2013_12_06_12.info.dat

Ex 脚本：

@echo off
set /p start= Start Date:
set /p end= End Date:
copy /b ????

前用户输入：2013_12_02 和 2013_12_05

Ex 输出：合并文件 2013_12_02 到 2013_12_05。

提前感谢您的帮助。

Answer 1

我假设你知道你在做什么，并且连接你的二进制文件是有效的。

只要符合 FOR 过滤器的所有文件都是合并的候选文件，并且用户始终以正确的格式 (yyyy_mm_dd) 输入日期，则以下内容应该有效：

@echo off
setlocal
set /p start= Start Date:
set /p end= End Date:
set "out=output.info.dat"
for %%F in (data_????_??_??_??.info.dat) do (
  for /f "tokens=1-3 delims=_" %%A in ("%%F") do (
    if "%%A_%%B_%%C" geq "%start%" if "%%A_%%B_%%C" leq "%end%" (
      copy /b "%out%"+"%%F" "%out%" /b
    )
  )
)

作为使用 COPY 的替代方法，您应该能够重定向 FINDSTR 的输出并获得相同的结果。

@echo off
setlocal
set /p start= Start Date:
set /p end= End Date:
>output.info.dat (
  for %%F in (data_????_??_??_??.info.dat) do (
    for /f "tokens=1-3 delims=_" %%A in ("%%F") do (
      if "%%A_%%B_%%C" geq "%start%" if "%%A_%%B_%%C" leq "%end%" (
        findstr "^" "%%F"
      )
    )
  )
)

我不确定哪个更快，COPY 或 FINDSTR

Answer 2

它几乎没有检查任何东西。小心点。

询问开始和结束日期。根据数据输入生成最小和最大文件并遍历文件的有序列表。如果找到一个文件，则使用findstr 读取它（第一个选项是type 命令，但它会慢4 到5 倍）并将所有输出重定向到最终合并文件。

@echo off
    setlocal enableextensions disabledelayedexpansion

    set /p "start=Start date :"
    set /p "end=End date   :"

    set "start=data_%start%_00.info.dat"
    set "end=data_%end%_99.info.dat"

    >merged.info.dat (
        for /f "tokens=*" %%f in ('dir /on /b "data_????_??_??_??.info.dat"') do (
            if /i "%%f" geq "%start%" if /i "%%f" leq "%end%" findstr "^" "%%f"
        )
    )

对于很长的文件列表，可以缩写搜索。在这一刻我不知道如何跳过文件列表中最初的不匹配部分，但最后的部分可以很容易地跳过

@echo off
    setlocal enableextensions disabledelayedexpansion

    set /p "start=Start date:"
    set /p "end=End date:"

    set "start=data_%start%_00.info.dat"
    set "end=data_%end%_99.info.dat"

    >output.info.dat (
        for /f "tokens=*" %%f in ('dir /on /b "data_????_??_??_??.info.dat"') do (
            if /i "%%f" geq "%start%" if /i "%%f" leq "%end%"  ( findstr "^" "%%f" ) else ( goto :endMerge )
        )
    )
:endMerge