使用 UPDATE 的语法错误 SQL 查询

Question

上下文

我在我的网站上添加了修改密码和电子邮件地址的选项。我有一个 Microsoft Access 数据库。它在“Login”表中有“EmailAddress”、“Password”和“Username”列。

代码

'For testing purposes, lets say :
VB_PasswordTXT = "1000:8NHLJo5oIDugFdzscuMrNSKyoNTRa0kI:6NSlpqGYC4zU2BG6cfJaHaPgVRCDPCc2"
VB_UserNameTXT = "Test123"
VB_EmailTXT = "a@mail.com"

Using thisConnection As New OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=""path""")
    Using thisCommand As OleDbCommand = thisConnection.CreateCommand
        ' Open connection object
        thisConnection.Open()

        ' Initialize SQL SELECT command to retrieve desired data
        thisCommand.CommandText = "UPDATE Login SET EmailAddress = @EmailAddress, Password = @Password " & _
                                "WHERE Username = @Username"
        thisCommand.Parameters.AddWithValue("@Username", VB_UserNameTXT)
        thisCommand.Parameters.AddWithValue("@EmailAddress", VB_EmailTXT)
        thisCommand.Parameters.AddWithValue("@Password", VB_PasswordTXT)

        ' Create a DataReader object based on previously defined command object
        Dim thisReader As OleDbDataReader = thisCommand.ExecuteReader() 'Crashes here
        If thisReader.Read() Then
        End If

        thisReader.Close()
        thisConnection.Close()
    End Using
End Using

崩溃日志

UPDATE 命令中的语法错误。 （法语免费翻译）

问题

（据我所知），问题来自UPDATE 语法。它有什么问题？

Answer 1

密码是 MS-Access 中的 reserved keyword。
当你有一个以这种方式命名的字段时，你应该将它括在方括号中

  thisCommand.CommandText = "UPDATE Login SET EmailAddress = @EmailAddress, " & _
                            "[Password] = @Password " & _
                            "WHERE Username = @Username"

如果仍然可行，我建议更改该名称

而且，当 ExecuteReader 工作时，用于 UPDATE/INSERT/DELETE sql 的正确方法是

    thisCommand.ExecuteNonQuery() 

调用 ExecuteReader 不好，因为您强制它创建一个在更新时不需要的 OleDbDataReader。

编辑
阅读您的最后一条评论，我注意到您在集合中以错误的顺序添加了参数。 OleDb 不通过名称识别参数，而是通过它们在参数集合中的位置来识别参数。您应该按照它们各自占位符在命令文本中出现的确切顺序添加它们（将用户名移动到最后添加的用户名）

   thisCommand.CommandText = "UPDATE Login SET EmailAddress = @EmailAddress, " & _ 
                             "[Password] = @Password " & _
                             "WHERE Username = @Username"
    thisCommand.Parameters.AddWithValue("@EmailAddress", VB_EmailTXT)
    thisCommand.Parameters.AddWithValue("@Password", VB_PasswordTXT)
    thisCommand.Parameters.AddWithValue("@Username", VB_UserNameTXT)