将 Excel 发布为网页

Question

我正在尝试使用 VB 脚本将 excel 保存为网页。我面临的问题是excel中的工作表名称（例如Sheet1）也保存在网页中。我不希望工作表名称出现在网页中。

我发现的一个解决方案是，如果将 excel 作为网页发布（而不是另存为网页），那么它将不包含工作表名称。但是我在尝试使用 VB 脚本时遇到了问题。下面是代码：

Dim objApp, objBook, objRange, objSheet
Set objApp = CreateObject("Excel.Application")
objApp.Visible = False
Set objBook = objApp.Workbooks.Open("C:\Dashboard\excel_files\Account Executive.xlsx")
Set objSheet = objBook.worksheets("Account Executive")
Set objRange = objSheet.Range("C5:I30")

With objBook.PublishObjects.Add(xlSourceRange, "C:\EXCEL_TO_HTML_RANGE.htm", "Account Executive", objRange.Address, xlHtmlStatic, "Title of the page").Publish(True) 
End With


objBook.Close
objApp.Quit
Set objSheet = Nothing
Set objRange = Nothing
Set objApp = Nothing

此代码给出一个未知的运行时错误，代码为 800A03EC。 是否有更正此代码或其他方式从网页中删除工作表名称？

提前致谢。 :)

感谢@AxelRichter excel 2010 的最终工作代码：

Dim objApp, objBook, objRange, objSheet

Set objApp = CreateObject("Excel.Application")

objApp.Visible = False

Set objBook = objApp.Workbooks.Open("C:\Dashboard\excel_files\OU Dashboard.xlsx")
Set objSheet = objBook.worksheets("OU Dashboard")
Set objRange = objSheet.Range("C5:J30")

Dim oPOs, oPO
Set oPOs = objBook.PublishObjects
Set oPO = oPOs.Add(4, "C:\Dashboard\EXCEL_TO_HTML_RANGE.htm", "OU Dashboard", "$C$5:$J$30", 0, "TableDIVID", "Title of the page")
oPO.Publish (True)

set oPO = Nothing
set oPOs = Nothing
Set objSheet = Nothing
Set objRange = Nothing


objBook.Close False
set objBook = Nothing 
objApp.Quit
Set objApp = Nothing

Answer 1

您的代码存在三个问题。

首先：常量xlSourceRange 和xlHtmlStatic 可能是未定义的。因此，请改用它们的值。有关 XlSourceType 和 XlHTMLType，请参阅 https://msdn.microsoft.com/en-us/library/office/ff823068.aspx。

第二：With需要Add返回的对象，而不是Publish的响应。

第三：你把DivID和Title搞混了。

Dim objApp, objBook, objRange, objSheet
Set objApp = CreateObject("Excel.Application")
objApp.Visible = False
Set objBook = objApp.Workbooks.Open("C:\Dashboard\excel_files\Account Executive.xlsx")
Set objSheet = objBook.worksheets("Account Executive")
Set objRange = objSheet.Range("C5:I30")

With objBook.PublishObjects.Add(4, "C:\EXCEL_TO_HTML_RANGE.htm", "Account Executive", objRange.Address, 0, "TableDIVID", "Title of the page")
 .Publish(True) 
End With


objBook.Close False
objApp.Quit
Set objSheet = Nothing
Set objRange = Nothing
Set objApp = Nothing

With .. End With可以替换为以下代码进行调试：

...
Dim oPOs, oPO
Set oPOs = objBook.PublishObjects
Set oPO = oPOs.Add(4, "C:\EXCEL_TO_HTML_RANGE.htm", "Account Executive", "$C$5:$I$30", 0, "TableDIVID", "Title of the page")
oPO.Publish (True)
...