如何按类从特定 URL 中获取 href？

Question

我需要 Excel VBA 代码，当用户名输入到电子表格中的特定单元格时触发。然后导航到在本例中是工作目录的网页。然后它找到 div 类“panel bg-brick-red managed-by”> 并将与该类关联的 href 作为字符串返回。

然后我希望从该字符串中提取 href 的特定部分并将其粘贴到电子表格中的单元格中。

因此，您在电子表格中的特定单元格中输入用户名以触发 sub，它会导航到我们内部目录的 url 以查找此人，然后从该页面中获取他们的直线经理的工资号码，从 href 中剥离该号码从 href 中支付号码，然后将结果粘贴到 Excel 中指定的结果单元格中。

Answer 1

从字符串中提取内容的一种灵活方法是使用正则表达式模式匹配。添加对 Microsoft Internet Controls 的引用。

Option Explicit

Sub ExtractFromURL()

    Dim IE As Object, URL As String
    Dim links As Object, link As Object
    Dim href As String, PayNo As String
    
    Set IE = New InternetExplorerMedium
    IE.Visible = True
    
    URL = "http://some/web/page"
    IE.navigate URL
    
    Do Until IE.readyState >= 4
        DoEvents
    Loop
    
    ' find element
    Set links = IE.document.getElementsByClassName("panel bg-brick-red managed-by")
    Set link = links(0).getElementsByTagName("a")
    href = link(0).href
    
    ' build regex to pattern match PayNp
    Dim regex As Object, m As Object 'match
    Set regex = CreateObject("vbscript.regexp")
    With regex
       .Global = False
       .MultiLine = False
       .IgnoreCase = True
       .Pattern = "(\d{5,6})" 'a number with 5 to 6 digits
    End With
    
    ' extract number
    If regex.test(href) Then
         Set m = regex.Execute(href) ' match
         PayNo = m(0)
         MsgBox PayNo & " extracted from " & href
    Else
         MsgBox "No number in " & href
    End If
    IE.Quit
    
End Sub