比较双打返回 false

Question

我的数据库中有三个数字，想在 if 语句中比较它们。

我有一个简单的 convert 函数，它只返回双精度数。

Public Function RetDbl(ByVal obj As Variant) As Double
    On Error Resume Next
    RetDbl = val(Replace(Nz(obj, 0), ",", "."))
End Function

声明是

If RetDbl(rs.value("NumA")) + RetDbl(rs.value("NumB")) <> (RetDbl(rs.value("NumC")) * 1000) Then
    '[... do some code ...]
End If

使用RetDbl(rs.value("NumA")) = 0.33、RetDbl(rs.value("NumB") = 0.5 和RetDbl(rs.value("NumC")) = 0.00083

这总是返回 false

我也试过了：

在直接字段 (STRG + G) 中：?cdbl(0.33) + cdbl(0.50) = cdbl(0.83) 返回 false。当我省略最后一部分时，它返回0.83

如何比较这些数字？

Answer 1

比较浮点数很难。就在昨天，我发了this question

我的解决方案：

Public Function DblSafeCompare(ByVal Value1 As Variant, ByVal Value2 As Variant) As Boolean
    'Compares two variants, dates and floats are compared at high accuracy
    Const AccuracyLevel As Double = 0.00000001
    'We accept an error of 0.000001% of the value
    Const AccuracyLevelSingle As Single = 0.0001
    'We accept an error of 0.0001 on singles
    If VarType(Value1) <> VarType(Value2) Then Exit Function
    Select Case VarType(Value1)
        Case vbSingle
            DblSafeCompare = Abs(Value1 - Value2) <= (AccuracyLevelSingle * Abs(Value1))
        Case vbDouble
            DblSafeCompare = Abs(Value1 - Value2) <= (AccuracyLevel * Abs(Value1))
        Case vbDate
            DblSafeCompare = Abs(CDbl(Value1) - CDbl(Value2)) <= (AccuracyLevel * Abs(CDbl(Value1)))
        Case vbNull
            DblSafeCompare = True
        Case Else
            DblSafeCompare = Value1 = Value2
    End Select
End Function

请注意，AccuracyLevel (epsilon) 可以设置为较小的值，我对单打和双打使用相同的值，但它对我的目的来说效果很好。

我使用的是相对 epsilon，但将它与第一个值相乘，而不是最大值，因为如果存在显着差异，则比较无论如何都会失败。

请注意，我使用的是 <= 而不是 <，因为否则 DblSafeCompare(cdbl(0) ,cdbl(0)) 会失败

请注意，此函数检查类型是否相等，因此将整数与长整数、双精度数与单数等进行比较都失败了。但是，将 Null 与 Null 传递进行比较。

实现它：

?DblSafeCompare(cdbl(0.33) + cdbl(0.50) ,cdbl(0.83))
?DblSafeCompare(cdbl(0.331) + cdbl(0.50) ,cdbl(0.83))

Answer 2

比较浮点数确实是一个问题，如果您尝试在不了解浮点数的性质的情况下进行比较。

这是一篇关于它的好文章 - https://docs.oracle.com/cd/E19957-01/806-3568/ncg_goldberg.html 和 How dangerous is it to compare floating point values?

一般来说，这个问题是如此之大，以至于像 C# 这样的一些语言已经开发了一个名为 Decimal 的特定类，它可以让比较像非程序员所期望的那样运行。 Decimal info。在VBA 中，类似的类是Currency。因此

CCur(0.33) + CCur(0.50) = CCur(0.83)

返回True。 VBA 支持函数CDec，它将双精度数转换为十进制数，但不支持类Decimal。因此：

CDec(0.33) + CDec(0.50) = CDec(0.83)

也会返回True。并且比Currency 具有更好的准确性。 CDec documentation.