Monad Transformer (RandT) 中的多个独立 ST/State monad...复杂的包装/展开

Question

只是学习如何更直观地掌握单子和转换器；很多看起来很明显的事情对我来说仍然有点棘手哈哈。

所以我有一个位于Rand monad 中的计算，但在里面，还有另一个“子计算”（或多个）位于ST monad（或State monad，不管怎样……ST 仅用于性能，但我认为 State 在这种情况下也同样有效）。

整个计算不需要在 ST monad 内......并且这个子计算将以不同的起始状态多次调用，所以我不想将整个事情强制转换为 @ 987654327@（除非这是惯用方式）。

没有随机性，结构如下：

main = print mainComp

mainComp :: Int
mainComp = otherComp + (subComp 1) + (subComp 2)

subComp :: Int -> Int
subComp n = runST $ do
  -- generate state based on n
  -- ...
  replicateM_ 100 mutateState
  -- ...
  -- eventually returns an ST s Int

mutateState :: ST s ()
mutateState = -- ...

基本上一切都很好，mainComp 和 subComp 的引用完全透明。

这就是我目前使用Rand 的方式--

main = (evalRandIO mainComp) >>= print

mainComp :: (RandomGen g) => Rand g Int
mainComp = do
  subResultA <- subComp 1
  subResultB <- subComp 2
  return $ otherComp + subResultA + subResultB

subComp :: (RandomGen g) => Int -> Rand g Int
subComp = return $ runST $ do           -- is this ok to just throw in return?
  -- generate state based on n
  -- ...
  replicateM_ 100 mutateState
  -- ...
  -- eventually returns an ST s Int (??)

mutateState :: ??
mutateState = ??

如果我想使用随机种子和其中的Rand monad，mutateState 应该是什么类型？我想我可能想使用RandT g (ST s) () 的返回类型，但我如何使它与subComp 中的runST 中预期的类型相匹配？

Answer 1

使用 monad 转换器，您可以按照添加它们的相反顺序“剥离”层。所以，如果你有RandT g (ST s) () 类型的东西，你首先使用evalRandT 或runRandT 消除RandT，然后才调用runST。

下面是结合RandT 和ST 的简单示例：

import Data.STRef
import System.Random

import Control.Monad
import Control.Monad.Trans
import Control.Monad.ST
import Control.Monad.Random
import Control.Monad.Random.Class

stNrand :: RandT StdGen (ST s) Int
stNrand = do
    ref <- lift $ newSTRef 0
    i <- getRandomR (0,10)
    lift $ writeSTRef ref i
    lift $ readSTRef ref

main :: IO ()
main = putStrLn . show $ runST $ evalRandT stNrand (mkStdGen 77)

编辑：这是一个扩展版本，现在有一个函数runSTBelowRand，可让您在Rand StdGen a 计算中嵌入RandT StdGen (ST s) a 计算。该函数使用getSplit分割全局计算的种子，并将新的种子提供给子计算。

{-# LANGUAGE RankNTypes #-}

import Data.STRef
import System.Random

import Control.Monad
import Control.Monad.Trans
import Control.Monad.ST
import Control.Monad.Random
import Control.Monad.Random.Class

stNrand :: RandT StdGen (ST s) Int
stNrand = do
    ref <- lift $ newSTRef 0
    i <- getRandomR (0,10)
    lift $ writeSTRef ref i
    lift $ readSTRef ref

runSTBelowRand :: (forall s. RandT StdGen (ST s) a) -> Rand StdGen a
runSTBelowRand r = do
    splittedSeed <- getSplit
    return $ runST $ evalRandT r splittedSeed

globalRand :: Rand StdGen (Int,Int)
globalRand = do
    i1 <- runSTBelowRand stNrand
    -- possibly non-ST stuff here
    i2 <- runSTBelowRand stNrand
    return (i1,i2)

main :: IO ()
main = putStrLn . show $ evalRand globalRand (mkStdGen 77)