如果多个单子“混合”，是否可以利用单子结构？

Question

考虑以下代码：

run = runExcept $ do
  case Just 1 of
    Nothing -> throwE "escape 1"
    Just x -> do
      case Just 2 of
        Nothing -> throwE "escape 2"
        Just y -> do
          case Just 3 of
            Nothing -> throwE "escape 3"
            Just z -> return z

假设Just 1、Just 2、Just 3 是返回Maybe Int 的函数调用。

整个函数都在ExceptT 中，因为我想抛出异常。但里面真的只是很多 Maybe 值被操纵。

那么，我是否有可能利用 Maybe monad 的行为来避免出现阶梯状，同时仍然能够抛出异常？

Answer 1

您似乎希望使用与哪个失败相关的信息来丰富一系列Maybe 操作（如果有）。为什么不将 enriching 实现为一个简单的函数？

enrich :: MonadError e m => e -> Maybe a -> m a
enrich e Nothing = throwError e
enrich e (Just x) = return x

我正在使用 MonadError - 单子类 m 可以抛出 e 类型的错误 - 泛化 enrich 的类型。例如，我们可以将其用作e -> Maybe a -> Except e a 或e -> Maybe a -> Either e a 类型，因为Except 和Either 都是MonadError 的实例。

现在您只需使用enrich 将您的Maybe 值一次提升到更丰富的一元上下文中。

action = do
    x <- enrich "escape 1" maybe1  -- look mum, no staircasing!
    y <- enrich "escape 2" maybe2
    z <- enrich "escape 3" maybe3
    return [x, y, z]

---

如果你应用性地使用你的monad——也就是说，你没有使用早期的结果来确定以后的计算——有一种惯用的方法来推广这个函数来处理任意数量的@ 987654338@s。我们将把Maybes 连同我们需要丰富它的额外数据一起放入一个列表中——在这种情况下，是错误消息。然后我们可以traverse (née mapM) 列表来丰富其中的每个Maybe 并将它们加入到更大的单子动作中。

enrichMaybes :: (Traversable t, MonadError e m) => t (e, Maybe a) -> m (t a)
enrichMaybes = traverse (uncurry enrich)

action = enrichMaybes [("escape 1", maybe1), ("escape 2", maybe2), ("escape 3", maybe3)]

像这样将效果视为一等公民的能力就是为什么函数式编程是一件好事。