Haskell 函数遍历列表中的每一对并返回一个大小比原始列表小 1 的列表

Question

假设我们有列表 [1,2,3,4]。 我想获取每对连续元素（即（1,2），（2,3），（3,4）），将它们应用于某个函数，并返回包含该函数结果的列表。 我不太明白，如何在 haskell 上执行此操作，因为我们这里实际上没有循环和数组。

Answer 1

您可以尝试以下一些方法来解决此问题。第一步是获取对，第二步是将函数应用于对。完成第一步的一种方法是使用递归函数。现在在 Haskell 列表中使用 [] 和 :，[1,2,3] 是 1:(2:(3:[])) 的语法糖。所以让我们编写我们的函数：

window [] = []
window [a] = []
window [a,b] = [(a,b)]
window (a:b:r) = (a,b):window (b:r)

我们可以做到这一点的另一种方法是使用函数zip。回想一下，这需要两个列表，将它们的元素配对，并在任一输入结束时结束列表。

window [] = []
window xs = zip xs (tail xs)

第二步是将我们的函数应用于配对。我们可以通过map (uncurry f) 做到这一点。一起来：

onWindow f = map (uncurry f) . window

Answer 2

这里有几种方法可以奏效。

你可以使用递归：

mapCons :: (a -> a -> b) -> [a] -> [b]
-- input has at least two elements
mapCons f (a0:a1:as) =
  -- use them to compute the head of the output
  f a0 a1 :
  -- reuse the second element to compute the tail of the output
  mapCons f (a1:as)
-- input has less than two elements, so output is the empty list
mapCons _ _ = []

或者，zip 将一对列表转换为一对列表：

λ zip [1..10] ['a'..'z']
[(1,'a'),(2,'b'),(3,'c'),(4,'d'),(5,'e'),(6,'f'),(7,'g'),(8,'h'),(9,'i'),(10,'j')]

这提供了一种方法来生成列表中的所有连续对，方法是使用自己的尾部压缩列表：

λ zip [1..10] ['a'..'z']
[(1,'a'),(2,'b'),(3,'c'),(4,'d'),(5,'e'),(6,'f'),(7,'g'),(8,'h'),(9,'i'),(10,'j')]

然后您可以使用map 在列表中的每一对上运行您的函数

λ map (\(a,b) -> 10*a + b) $ zip [0..9] (tail [0..9])
[1,12,23,34,45,56,67,78,89]

这是一个足够常见的模式，有一个结合map和zip的函数：zipWith：

λ :t zipWith
zipWith :: (a -> b -> c) -> [a] -> [b] -> [c]
λ zipWith (\a b -> 10*a + b) [0..9] (tail [0..9])
[1,12,23,34,45,56,67,78,89]