在“PROD”和“DEV”模式之间快速切换

Question

我使用一些高级自动化宏开发 VBA 代码，这些宏在 DEV 阶段执行“管道”和额外调试。 但是，当我将文件发送给用户（PROD 阶段）时，我希望将所有这些都关闭。

DEV 和 PROD 之间的切换经常发生（git + devops 方法）。

在 DEV 和 PROD 之间实现快速“切换”的最佳/最优雅的方式是什么？ 是的，我可以只使用全局 Const isDebug（我在某些项目中这样做过），但它很繁琐、不优雅且容易出错（我不止一次忘记“翻转”开关——正如我之前所说的那样，快速而敏捷“几乎”CI/CD 管道）。

编辑

现在我正在使用一种快速的脏破解（我不喜欢脏破解）来检查 Excel 文件是否从路径中带有我的登录名的位置运行。如果是 - 这意味着我正在处理文件。如果没有 - 其他人正在使用它，我们不需要任何调试模式。但它很丑陋，而且我可以预见很多问题（例如，明天其他人可能正在开发这些 VBA……因此必须重写调试代码）。

Answer 1

您可以使用工作簿路径中的文本文件作为条件。

如果文件丢失（例如'DebugMode.txt'）或未设置调试选项（文本文件中的'DebugMode:On'），请关闭调试模式，否则将其打开。

如果您在没有文本文件的情况下部署工作簿，调试模式将关闭。

如果其他人需要调试模式，请共享/创建文件。

示例代码：

Function IsDebugMode() As Boolean

Const DebugOptionFileName As String = "DebugMode.txt" 
Const DebugIsOnString As String = "DebugMode:On"
Const ForReading as Long = 1

Dim txtStream As Object
Dim DebugOptionFilePath As String

IsDebugMode = False
DebugOptionFilePath = ThisWorkbook.Path & "\" & DebugOptionFileName

With CreateObject("Scripting.Filesystemobject")
    If .FileExists(DebugOptionFilePath) Then
        Set txtStream = .OpenTextFile(DebugOptionFilePath, ForReading, False)
        Do Until txtStream.AtEndOfStream
            If txtStream.ReadLine = DebugIsOnString Then
                IsDebugMode = True
                Exit Do
            End If
        Loop
    End If
End With

End Function

Answer 2

在 VBE 中转到 Extras -> VBAProject 的属性 并输入编译参数，例如：

DEV_MODE = -1

^{对不起，德国人的截图。}

然后使用下面的代码

Option Explicit

Sub test()
    'the following #If is a compile condition
    #If DEV_MODE Then
        'this is only compiled in dev mode
        Debug.Print "debug mode is on"
    #Else
        'this is only compiled in production mode
        Debug.Print "debug mode is off"
    #End If
End Sub

请注意，在 VBA 中，-1 是 True，0 是 False。切换编译参数DEV_MODE = -1将切换整个VBA项目的开发模式。

Answer 3

我不喜欢将开关作为编译器设置的尝试 - 忘记更改它比更改 Const 定义更有可能。

我发现您尝试检查用户名、设备名、文件路径或类似的东西还不错。只需将逻辑放入一个返回boolean 的小函数isTestMode()（即使它是单行）。在这个功能中，如果另一个人将接管工作，很容易改变逻辑。使用此函数（仅此而已！）来检查是否执行您的调试语句。

Public Function isTestMode() as boolean
    ' Checking current user
    isTestMode = (environ("Username") = "FunThomas")
    ' Checking device name
    isTestMode = (environ("ComputerName") = "MySuperPC")
    ' Checking if a specific file is present
    isTestMode = Dir(thisworkbook.Path & "\IsTestMode") <> "")
End Function