如何将文本文件中列出的那些文件夹的文件和文件夹列表获取到列表文件中？

Question

我创建了一个批处理文件，用于将指定目录中的所有文件、文件夹和子文件夹导出到文本文件。我需要的是从包含其路径的文本文件中列出带有子文件夹的特定文件。批处理文件将列出仅包含在此文本文件中的文件和子文件夹。例如，我需要仅将这些文件夹下的文件导出到文本文件中，就像输入文本文件中一样。

C:\Users\Username\Documents\test1
C:\Users\Username\Documents\test2
C:\Users\Username\Documents\test3
C:\Users\Username\Documents\test4

提前致谢。

编辑添加更多细节；通常，我们使用这个命令列出一个目录下的所有文件：

dir > output.txt

我想应用另一种方法。我只想列出特定目录下的文件，文本文件将包含那些特定的目录路径。

这是文本文件：

C:\Users\Username\Documents\myfolder1
C:\Users\Username\Documents\myfolder2
C:\Users\Username\Downloads\yet another folder

虽然 Documents 和 Downloads 中还有许多其他文件夹，但只会列出路径在我的输入文本文件中列出的文件夹下的文件。然后，myfolder1、myfolder2 和 yet another folder 的所有子文件夹和文件将被发送到一个输出文本文件。

Answer 1

读取包含文件夹名称的文件并列出每个文件夹及其子文件夹中的文件：

@echo off
for /f "delims=" %%a in (file.txt) do dir /s /b "%%a\*"

根据您的需要调整dir 开关和文件掩码。

Answer 2

这个非常简单的批处理文件可用于此任务：

@echo off
rem First check existence of folders list file and exit
rem batch file execution if this file does not exist.

if not exist "%UserProfile%\Documents\FoldersList.txt" goto :EOF

rem Delete output list file if already existing from a previous execution.
rem The error message output on file not existing is suppressed by
rem redirecting it from handle STDERR (standard error) to device NUL.

del "%UserProfile%\Documents\OutputList.txt" 2>nul

rem For each folder path in folders list file run the command DIR to output
rem in bare format all files and folders including hidden files and folders
rem in the folder and all its subfolders with redirecting the output written
rem to handle STDOUT (standard output) to the output list file with appending
rem the new lines at end of the list file. The list file is automatically
rem created on first line written to the output list file.

for /F "usebackq eol=| delims=" %%I in ("%UserProfile%\Documents\FoldersList.txt") do dir "%%~I\*" /A /B /S >>"%UserProfile%\Documents\OutputList.txt"

通过将 DIR 选项 /A 替换为 /A-D 来生成没有文件夹的文件列表，这意味着除了属性目录之外的任何属性。这与使用 for last 命令行相同，不同之处在于内部 FOR 不输出具有隐藏属性集的文件：

for /F "usebackq eol=| delims=" %%I in ("%UserProfile%\Documents\FoldersList.txt") do for /R "%%~I" %%J in (*) do echo %%J>>"%UserProfile%\Documents\OutputList.txt"

要了解所使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• del /?
• dir /?
• echo /?
• for /?
• rem /?

另请参阅有关 Using command redirection operators 的 Microsoft 文章。