通过目录树递归的 Perl 脚本

Question

我想编写一个 Perl 脚本，它从目录树的顶部开始（在命令行参数中提供）并递归地遍历每个子目录，对每个文件执行特定操作。

我为此使用finddepth，但是当我在距离基目录两级或更高级别的目录上运行脚本时，它似乎不起作用。

这是我的代码：

#!/usr/local/bin/perl -w

use strict;

use File::Copy;
use File::Find;
use File::Basename;
use File::Path;

finddepth(\&file_list, @ARGV);

sub file_list {

    my ($file_path, $name, $path, $suffix);

    $file_path = $File::Find::name;

    ($name, $path, $suffix) = fileparse($file_path, /\.*/);

    my $fullname = $name . $suffix;
    my $file = $fullname;

    if ($file =~ /^[^\.].*[^\.pl]$/) {

        copy($file, "$file.orig");

        open(FILE, "$file");
        my @file_data = <FILE>;
        close(FILE);

        open(FOUT, ">$file") or die " \n File cannot be opened !";

        foreach my $line (@file_data) {
            if ($line =~ /^\s+Error:/) {
                $line =~ s/([^-]\d+)/ \*\*/gc;
                print FOUT $line;
            }
            else {
                print FOUT $line;
            }
        }
        close(FOUT);
    }
}

始终抛出以下警告/错误：

1. 读取关闭的文件句柄
2. 无法打开文件！

我似乎无法弄清楚为什么会这样。我试图让我的问题尽可能具体。如果您需要更多信息，请告诉我。谢谢。

Answer 1

您无法打开该文件，因为 $file 在那个时间点恰好是一个目录，因此您需要为此添加一个检查。

在打开文件进行阅读时，可能值得添加 or die 语句。

还要注意File::Find 将$_ 设置为当前文件名，因此生成$file 的5 行实际上是不必要的。

Answer 2

您的代码存在一些问题。

• use warnings 优于命令行-w

• 在第一次使用时声明变量，而不是在子例程顶部的块中

• 使用open的三参数形式，以及词法文件句柄

• 在检查open 调用的状态时，将内置变量$! 放入die 字符串中，以便您知道为什么打开失败

• 不要将标量变量放在双引号内。这可能是不必要的，并且在某些情况下可能会破坏您的代码。极不可能做任何你想做的事情

您的程序的这种重写使用use autodie 来避免需要显式的open ... or die $! 语句。它使用rename 来更改文件的名称，而不是复制它并覆盖原始文件。

我没有将整个文件读入内存，而是打开重命名的文件并逐行读取，编辑每一行并将其写入新文件

我已经编写了它，以便它忽略以点开头或以.pl 结尾的文件 - 我希望这是对的。我也很怀疑您的替换 s/[^-]\d+/ **/g 会查找前面不是连字符的字符的数字序列；是这样吗？

#!/usr/local/bin/perl

use strict;
use warnings;

use autodie;
no autodie 'unlink';

use File::Find 'finddepth';

finddepth(\&file_list, @ARGV);

sub file_list {

  return unless -f;
  return if /^\./ or /\.pl$/;

  my $file = $_;
  my $orig = "$file.orig";

  unlink $orig;
  rename $file, $orig;

  open my $infh, '<', $orig;
  open my $outfh, '>', $file;

  while (my $line = <$infh>) {
    if ($line =~ /^\s+Error:/) {
      $line =~ s/[^-]\d+/ **/g
    }
    print $outfh $line;
  }

  close $outfh;
}