如何在 Android Studio 项目中将库添加到 Gradle 构建？

Question

我想将以下库添加到我的项目的 Gradle 构建中。我要添加的库是：我已经下载的signal-protocol-java-2.8.1.jar。如何将它添加到 Gradle 构建中，以便将 .jar 中包含的类导入我正在开发的 java 类中？

这是我的build.gradle 文件：

buildscript {
    repositories {
        google()
        mavenCentral()
        jcenter {
            content {
                includeVersion 'org.jetbrains.trove4j', 'trove4j', '20160824'
                includeGroupByRegex "com\\.archinamon.*"
            }
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.0.1'
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.14'
        classpath "android.arch.navigation:navigation-safe-args-gradle-plugin:1.0.0-alpha09"
    }
}


ext {
    BUILD_TOOL_VERSION = '30.0.2'

    COMPILE_SDK = 30
    TARGET_SDK  = 30
    MINIMUM_SDK = 19

    JAVA_VERSION = JavaVersion.VERSION_1_8
}

wrapper {
    distributionType = Wrapper.DistributionType.ALL
}

allprojects {
    repositories {
        google()
        jcenter()
    }
}

subprojects {
    ext.lib_signal_service_version_number   = "2.15.3"
    ext.lib_signal_service_group_info       = "org.whispersystems"
    ext.lib_signal_metadata_version         = "0.1.2"

    if (JavaVersion.current().isJava8Compatible()) {
        allprojects {
            tasks.withType(Javadoc) {
                options.addStringOption('Xdoclint:none', '-quiet')
            }
        }
    }
}

task qa {
    group 'Verification'
    description 'Quality Assurance. Run before pushing.'
    dependsOn ':Signal-Android:testPlayProdReleaseUnitTest',
            ':Signal-Android:lintPlayProdRelease',
            ':libsignal-service:test',
            ':Signal-Android:assemblePlayProdDebug'
}

Answer 1

您必须编辑您的模块级build.gradle（您发布的是项目级）。它通常位于项目的“app”文件夹中。找到 dependencies 块并添加这一行：

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    ...
}

然后在这个 gradle 文件附近创建一个文件夹“libs”并将你的 .jar 库放在那里。将项目与 Gradle 同步。