将 AndroidAnnotations Maven 设置适配到 Gradle

Question

是否可以将 AndroidAnnotations Maven 设置适配到 Gradle 中？ http://code.google.com/p/androidannotations/wiki/MavenEclipse 我似乎无法让它工作我不断收到com.sun.codemodel#codemodel;2.5-FROZEN-AA: not found

到目前为止我有这个

description = "App"
abbreviation = "App"
version = '1.0.0.BUILD-SNAPSHOT'

buildscript {
    repositories {
        mavenRepo name: 'gradle-android-plugin', urls: 'http://jvoegele.com/maven2/'
        mavenRepo name: 'androidannotations', urls: 'http://repository.excilys.com/content/repositories/releases/'
    }

    def gradleAndroidPluginVersion = '1.0.0'

    dependencies {
        classpath "com.jvoegele.gradle.plugins:android-plugin:$gradleAndroidPluginVersion"
    }
}

apply plugin: 'android'
apply plugin: 'eclipse'
apply plugin: 'idea'

def compatibilityVersion = 1.6
sourceCompatability = compatibilityVersion
targetCompatibility = compatibilityVersion

repositories {
    mavenCentral()
    mavenRepo urls: 'http://maven.springframework.org/snapshot'
    mavenRepo urls: 'http://maven.springframework.org/milestone'
}

def roboguiceVersion = '1.1.1'
def guiceVersion = '2.0-no_aop'
def springAndroidVersion = '1.0.0.M4'
def commonsHttpClientVersion = '3.1'
def jacksonMapperVersion = '1.8.5'
def androidAnnotationsVersion = '2.1'

dependencies {
    compile "org.roboguice:roboguice:$roboguiceVersion"
    compile "com.google.inject:guice:$guiceVersion"
    compile "org.springframework.android:spring-android-rest-template:$springAndroidVersion"
    compile "commons-httpclient:commons-httpclient:$commonsHttpClientVersion"
    compile "org.codehaus.jackson:jackson-mapper-asl:$jacksonMapperVersion"
    compile "com.googlecode.androidannotations:androidannotations:$androidAnnotationsVersion"
    compile group: 'com.googlecode.androidannotations', name: 'androidannotations', version: '2.1', classifier: 'api'
    runtime files('lib/server-standalone.jar')
}

sourceSets {
    main {
        java {
            srcDir 'src'
        }
    }
}

clean {
    delete 'gen'
}

idea {
    module {
        downloadJavadoc = true
    }
    project {
        javaVersion = 'Android 2.2 Platform'
    }
}

androidProcessResources.dependsOn(clean)
eclipse.dependsOn(cleanEclipse)
idea.dependsOn(cleanIdea)

defaultTasks 'assemble'

Answer 1

作为第一个指针，我看不到托管 androidannotations 库的 maven 存储库的声明。

您应该将http://repository.excilys.com/content/repositories/releases 添加为 maven Repo：

...
repositories {
    mavenCentral()
    mavenRepo urls: 'http://maven.springframework.org/snapshot'
    mavenRepo urls: 'http://maven.springframework.org/milestone'
    mavenRepo urls: 'http://repository.excilys.com/content/repositories/releases'
}
...

问候

Answer 2

好的，我设法解决了它

我必须添加

repositories {
    mavenCentral()
    mavenRepo urls: 'http://maven.springframework.org/snapshot'
    mavenRepo urls: 'http://maven.springframework.org/milestone'
    mavenRepo urls: 'http://repository.excilys.com/content/repositories/releases'
    mavenRepo urls: 'http://repository.excilys.com/content/repositories/thirdparty'
}

springAndroidVersion = '1.0.0.M4'
commonsHttpClientVersion = '3.1'
jacksonVersion = '1.8.5'
androidAnnotationsVersion = '2.1.1'

dependencies {
    compile "org.springframework.android:spring-android-rest-template:$springAndroidVersion"
    compile "commons-httpclient:commons-httpclient:$commonsHttpClientVersion"
    compile "org.codehaus.jackson:jackson-mapper-asl:$jacksonVersion"
    compile "com.googlecode.androidannotations:androidannotations:$androidAnnotationsVersion"
    compile "com.googlecode.androidannotations:androidannotations:$androidAnnotationsVersion:api"
}