浏览目录的最佳方式是什么？

Question

下面的两个例子都可以，还是第二个例子不好？

案例1：留在顶层目录，使用catdir访问子目录

#!/usr/bin/env perl
use warnings; use strict;

my $dir = 'my_dir_with_subdir';
my ( $count, $dh );

use File::Spec::Functions;
$count = 0;

opendir $dh, $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    my $sub_dir = catdir $dir, $file;
    if ( -d $sub_dir ) {
        opendir my $dh, $sub_dir or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
    }
    else {
        $count++;
    }
}

closedir $dh or die $!;
print "$count\n";

案例2：切换到子目录，退出前恢复顶层目录

use Cwd;
my $old = cwd;
$count = 0;
opendir $dh, $dir or die $!;
chdir $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    if ( -d $file ) {
        opendir my $dh, $file or die $!;
        chdir $file or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
        chdir $dir;
    }
    else {
        $count++;
    }
}
closedir $dh or die $!;
chdir $old or die $!;
print "$count\n";

Answer 1

你的问题是你应该切换到你正在经历的目录还是留在顶级目录。

答案是：视情况而定。

例如，考虑File::Find。默认行为是确实更改目录。但是，该模块还提供了一个no_chdir 选项以防万一。

在您的示例中，File::Find 可能不合适，因为您不想递归所有子目录，而只想递归一个。这是一个基于File::Slurp::read_dir 的脚本变体。

#!/usr/bin/perl

use strict; use warnings;

use File::Slurp;
use File::Spec::Functions qw( catfile );

my ($dir) = @ARGV;

my $contents = read_dir $dir;
my $count = 0;

for my $entry ( @$contents ) {
    my $path = catfile $dir, $entry;
    -f $path and ++ $count and next;
    -d _ and $count += () = read_dir $path;
}

print "$count\n";

Answer 2

对于您的示例，最好更改为子目录，并且不要在最后更改回原始目录。那是因为每个进程都有自己的“当前目录”，所以你的 perl 脚本正在改变它自己的当前目录这一事实并不意味着 shell 的当前目录被改变了；保持不变。

如果这是更大脚本的一部分，那就不同了；我的一般偏好是不更改目录，只是为了减少对脚本中任何位置当前目录的混淆。

Answer 3

使用 File::Find，就像你已经建议的那样：)

使用模块来解决此类问题几乎总是比使用自己的模块更好，除非你真的想了解walking dirs...