检查目录的绝对路径或文件名是否有效

Question

我正在创建一个 bat 脚本，我应该检查一个变量是否包含有效的目录绝对路径，以及另一个变量是否包含适用于 Windows 8 及更高版本的文件的有效名称。

那么，我将如何进行这些检查？

谢谢

再见

Answer 1

这比大多数人意识到的要复杂得多。 SO和其他地方有很多关于这个主题的错误信息。有许多“解决方案”看似有效，但在某些情况下却失败了。

问题可以分为两部分：

1) 绝对或相对

您不能简单地将路径转换为使用 FOR 变量“%%~fF”或参数“%~f1”的完整路径并测试它是否与原始字符串匹配（忽略大小写），因为有无限数量的可以编写绝对路径的方式。一个有效的绝对路径可以包含任意数量的\..\ 或\.\。此外，绝对路径可能使用驱动器号，也可能是 UNC 路径。此外，绝对路径中可能包含任意数量的"。

我通过首先删除所有引号来测试路径是绝对路径还是相对路径，然后我使用 FINDSTR 来测试它是否以以下任一开头：

• 驱动器号，后跟冒号，后跟反斜杠
• 两个反斜杠

2) 文件或文件夹或不存在

使用IF EXISTS path 很容易判断路径是否有效。但是区分文件和文件夹比较困难。

在 DOS 时代，您可以检查 path\NUL 是否存在，如果存在，那么您就知道该路径是一个文件夹。不幸的是，很多人都误以为这在 Windows 下有效 - 在 Windows 下不可靠

另一个常见的尝试是测试path\ 是否存在，如果存在，则假设它必须是一个文件夹。这通常似乎可行，但如果路径涉及目录符号链接或联结，则它不起作用

我将使用的分类代码与 https://stackoverflow.com/a/8669636/1012053 几乎相同，只是我将其用于环境变量而不是批处理参数。

我使用 FOR 变量 ~a 修饰符来查看文件/文件夹属性。如果我找到d，那么它就是一个文件夹。如果我找到没有d 的属性，那么它就是一个文件。否则，如果我找不到属性，则它不存在。

另一种似乎可以准确判断文件夹是否存在的方法是测试path\*是否存在，但我对这种方法的经验较少。

---

所以把它们放在一起，我得到了

@echo off
setlocal
set var=test.bat

setlocal enableDelayedExpansion

:: Determine absolute or relative
echo(!var:^"=!|findstr /i "^[A-Z]:[\\] ^[\\][\\]" >nul && set "type=absolute" || set "type=relative"

:: Determine file or folder or not exists
for /f eol^=^ delims^= %%F in ("!var!") do (
  for /f "tokens=1,2 delims=d" %%A in ("-%%~aF") do if "%%B" neq "" (
    echo %%F = %type% folder
  ) else if "%%A" neq "-" (
    echo %%F = %type% file
  ) else (
    echo %%F does not exist
  )
)

Answer 2

这是不言自明的代码。 它需要一个包含要检查的路径的参数。

set "INPUT_PATH=%~1"
set "FULL_PATH=%~f1"
set "SHORT_PATH=%~s1"
if /i "%INPUT_PATH%"=="%FULL_PATH%" echo this is a full path 
if exist "%INPUT_PATH%" echo this is an existing path
if exist %SHORT_PATH%\NUL echo this is a directory