ORA01400 的自定义异常不起作用

Question

我正在做一项学校作业，我必须在所有 PL/SQL 中添加例外。由于我创建了一些序列和触发器来添加自动增量功能（这是 Oracle SQL），我想我应该为所有与 ORA-01400: cannot insert NULL into(...) 相关的触发器添加一个例外。

按照example here，我创建了一个包来存储我的自定义异常，因此我可以在所有实现自动增量的触发器中使用它：

CREATE OR REPLACE PACKAGE my_exceptions
AS
    insert_null_into_notnull EXCEPTION;
    PRAGMA EXCEPTION_INIT(insert_null_into_notnull, -1400);
END my_exceptions;
/

这是触发器之一：

CREATE OR REPLACE TRIGGER update_cust_id
BEFORE INSERT ON CUSTOMER
FOR EACH ROW
BEGIN
    SELECT pk_cust_seq.NEXTVAL INTO :NEW.CUST_ID FROM DUAL;
EXCEPTION
    WHEN my_exceptions.insert_null_into_notnull THEN
        DBMS_OUTPUT.PUT_LINE('Attempted to insert a null value into not nullable column.');
        RAISE;
END;
/

问题是当我尝试故意添加失败的插入时，我仍然得到典型的 Oracle 错误：ORA-01400: cannot insert NULL into (...)，而不是我想要的 DBMS_OUTPUT。

我看了几次网站上的例子，看不出有什么区别，除了异常是用在过程中而不是触发器中。那是问题吗？如果是这样，我怎样才能使它在触发器中工作？

（OBS。这只是一个演示错误处理的学校练习；DBMS_OUTPUT 在这种情况下可能没有用，但这与本练习无关）

Answer 1

问题正如您在评论中提到的那样。在before 触发器触发并完成后，insert 引发 ORA-01400。如果不是这种情况，您将无法从触发器自动设置不可为空的列 - 例如，从序列设置主键值（模仿自动增量 ID），就像您设置 @ 987654324@。在附加到触发器的 PL/SQL 块中没有引发异常。

您可以在触发器中手动明确地检查每个不可为空的列，如果有任何为空的，则引发您自己的异常，但实际上您只是在复制内置功能。并且假设您跟踪列定义 - 如果您更改列的可空性，您必须记住更新触发器以匹配，除非您认为在运行时动态检查列 - 这将是如果可能的话，充其量是棘手的（使用dbms_sql）。

如果您的任务实际上不需要这种自定义处理，那么似乎付出了很多努力却没有真正的收获。甲骨文recommend you don't use triggers when you can use constraints；我知道这是一种练习，但即便如此，这也不是你想做的事情。

---

在您显示的触发器中强制出现运行时错误的一种方法是操纵序列，以便您尝试超过其MAXVALUE：

CREATE TABLE customer (cust_id NUMBER PRIMARY KEY, name VARCHAR2(20));

CREATE SEQUENCE pk_cust_seq MINVALUE 1 MAXVALUE 3 NOCYCLE;

CREATE OR REPLACE TRIGGER update_cust_id
BEFORE INSERT ON CUSTOMER
FOR EACH ROW
BEGIN
    SELECT pk_cust_seq.NEXTVAL INTO :NEW.CUST_ID FROM DUAL;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('Unable to create cust_id.');
        RAISE;
END;
/

那么前三个插入会起作用，第四个会失败：

set serveroutput on
insert into customer(name) values ('Customer 1')

1 rows inserted.

insert into customer(name) values ('Customer 2')

1 rows inserted.

insert into customer(name) values ('Customer 3')

1 rows inserted.

insert into customer(name) values ('Customer 4')

Error starting at line : 24 in command -
insert into customer(name) values ('Customer 4')
Error report -
SQL Error: ORA-08004: sequence PK_CUST_SEQ.NEXTVAL exceeds MAXVALUE and cannot be instantiated
ORA-06512: at "SCHEMA.UPDATE_CUST_ID", line 6
ORA-04088: error during execution of trigger 'SCHEMA.UPDATE_CUST_ID'
08004. 00000 -  "sequence %s.NEXTVAL %s %sVALUE and cannot be instantiated"
*Cause:    instantiating NEXTVAL would violate one of MAX/MINVALUE
*Action:   alter the sequence so that a new value can be requested
Unable to create cust_id.

你已经有了序列，所以在你的情况下，你可以alter sequence 将maxvalue 限制在你当前的最高值之​​上，并确保设置了nocycle；然后导致错误，并在您完成测试后将其重置为高值。

另外，顺便说一句，如果您使用的是 11g，则有两种方法可以将序列号分配给列；在 11g 之前，您必须按照您的说明进行操作：

SELECT pk_cust_seq.NEXTVAL INTO :NEW.CUST_ID FROM DUAL;

...但现在你可以这样做了：

:NEW.CUST_ID := pk_cust_seq.NEXTVAL;

Answer 2

试试这个：

应该是这样的：

CREATE OR REPLACE TRIGGER update_cust_id
BEFORE INSERT ON CUSTOMER
FOR EACH ROW
BEGIN
  BEGIN
    SELECT pk_cust_seq.NEXTVAL INTO :NEW.CUST_ID FROM DUAL;
  EXCEPTION
    WHEN OTHERS THEN
     IF (SQLCODE=01040) THEN   
       RAISE my_exceptions.insert_null_into_notnull;
    ELSE
       RAISE;
  END;

EXCEPTION
 WHEN my_exceptions.insert_null_into_notnull THEN
   DBMS_OUTPUT.PUT_LINE('Attempted to insert a null value into not nullable column.');
   RAISE;
END;