Applescript 创建文件夹并在文件存在时移动文件

Question

我有一个目标文件夹中的文件列表：

示例/HUVEC.csv
示例/HUVEC-1.csv
示例/HUVEC-3.3.2n-1.csv（随机散列）
示例/Endo1.csv

如果“示例”文件夹中有以“HUVECxxx”开头的文件，我希望能够创建一个名为“HUVEC”的文件夹，然后将“HUVECxxx”开头的文件移动到“ HUVEC”文件夹。

这是我目前所拥有的，已从简单版本修改（见下文）

set mgFilesFolder to choose folder with prompt "Where are the files stored which you would like to move to the destination?"

tell application "Finder"
set fileList to files of mgFilesFolder

repeat with aFile in fileList
    set prefix to name of aFile
    if prefix starts with "HUVEC" and (exists folder (HUVEC_folder)) then
        move aFile to HUVEC_folder
    else
        set HUVEC_folder to make new folder in mgFilesFolder with properties {name:"HUVEC"}
    end if
end repeat

repeat with aFile in fileList
    set prefix to name of aFile
    if prefix starts with "HUVEC" then move aFile to HUVEC_folder
end repeat


end tell

更简单的版本适用于一个文件

set mgFilesFolder to choose folder with prompt "Where are the files stored which you would like to move to the destination?"

tell application "Finder"
set fileList to files of mgFilesFolder

repeat with aFile in fileList
    set prefix to name of aFile
    if prefix starts with "HUVEC" and   set HUVEC_folder to make new folder in mgFilesFolder with properties {name:"HUVEC"}
    end if
end repeat

repeat with aFile in fileList
    set prefix to name of aFile
    if prefix starts with "HUVEC" then move aFile to HUVEC_folder
end repeat


end tell

但是我很确定多个文件的问题是，如果文件夹已经存在，那么脚本就会失败。

基本上我认为最大的问题是如何检查一个文件夹是否存在，否则应该创建！
感谢您的帮助，在 Applescript 中仍然相对较新。

Answer 1

您可以利用 AppleScript 的关键字every，而不是手动循环文件，它：

指定容器中的每个对象 (ref.)

当您使用这个方便的小功能时，脚本如下所示：

    property prefix : "HUVEC" -- The prefix for file sorting

    set mgFilesFolder to choose folder with prompt "Where are the files stored?"


    tell application "Finder"
        
        -- Retrieve all files that have names
        --  beginning with the prefix
        set fileList to every file of folder mgFilesFolder ¬
            whose name starts with prefix
        
        if fileList is {} then return "No files to move." -- Nothing to do
        
        
        -- Check to see if a folder with the right
        -- name exists; if not, create it.
        if not (exists folder named prefix in folder mgFilesFolder) ¬
            then make new folder in folder mgFilesFolder ¬
            with properties {name:prefix}
        
        
        set prefix_folder to the ¬
            folder named prefix in the ¬
            folder mgFilesFolder
        
        
        -- Move the files into the folder and return
        -- a list of file references for them
        return move the fileList to the prefix_folder
        
    end tell

我在整个代码中放置了 cmets 来解释脚本的每个部分的作用。但是，我一次都不需要使用repeat 循环。

您的另一个问题是尝试将文件名和目标文件夹是否存在的检查组合到一个命令中，该命令在repeat 循环中一遍又一遍地重复。我把所有东西都分开了，所以每一行代码都知道它在做什么，并且会做得很好。如果出现问题，很容易查明问题出在哪里：

1. 获取相关文件。
2. 如果没有，请停止脚本 - 无需继续。
3. 如果目标文件夹不存在，请创建它。
4. 获取目标文件夹的引用。
5. 将文件移动到目标文件夹中。

完成。

---

附录：Bash...？

您是否考虑过使用 bash 脚本来完成此类任务？对于大量文件，它的速度大约要快一万倍，下面是一个实现您想要的代码示例：

[[ -d HUVEC ]] && mv HUVEC*.csv HUVEC || { mkdir HUVEC && mv HUVEC*.csv HUVEC; }

?

Answer 2

CJK - 我做了一些修改，但仍然有一个小问题。下面的代码引入了另一个变量prefix1，以及我的另一个起始字符串"ENDO"。

脚本遵从并运行，甚至创建了prefix1 文件夹，但是"ENDO" 文件本身无法使用脚本末尾的两个return move... 命令移动。

我已经确认顺序很重要，即如果我切换行的顺序

return move the fileList1 to the prefix_folder1
return move the fileList to the prefix_folder

然后ENDO 文件被适当地移动，但HUVEC 文件无法移动。

    set prefixes to {"HUVEC", "ENDO"}

    set mgFilesFolder to choose folder with prompt "Where are the files stored?"


    tell application "Finder" to ¬
        repeat with prefix in prefixes

            set fileList to every file of folder mgFilesFolder ¬
                whose name starts with prefix

            if (count fileList) is not 0 then

                if not (exists folder named prefix in folder mgFilesFolder) ¬
                    then make new folder in folder mgFilesFolder ¬
                    with properties {name:prefix}

                set prefix_folder to the folder named prefix ¬
                    in the folder mgFilesFolder

                move the fileList to the prefix_folder

            end if
        end repeat