“编程”一个批处理文件，IF语句中的IF语句？

Question

为什么这段代码不能正常工作？

对不起，我无法理解如何发布代码，所以这里是代码的图像：

![在此处输入图片描述][1]（另外，请点击链接，因为我是新用户，还不能发布图片）

命令提示符甚至能够正确执行这个“分支 IF 命令”吗？ 如果是这样，我做错了什么？有谁知道？请回复！

:STARTEXITING
"D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Exit_Pass_1.txt
findstr /m "up to date" dbstatus_uTorrent_Exit_Pass_1.txt
if %error1eve1%==0 (
    SLEEP 2
    "D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Exit_Pass_2.txt
    findstr /m "up to date" dbstatus_uTorrent_Exit_Pass_2.txt
    if %error1eve1%==0 (
        SLEEP 3
        "D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Exit_Pass_3.txt
        findstr /m "up to date" dbstatus_uTorrent_Exit_Pass_3.txt
        if %error1eve1%==0 (
            process -q uTorrent.exe 15
            :STARTSTARTING
            "D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Start_Pass_1.txt
            findstr /m "up to date" dbstatus_uTorrent_Start_Pass_1.txt
            if %error1eve1%==0 (
                SLEEP 2
                "D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Start_Pass_2.txt
                findstr /m "up to date" dbstatus_uTorrent_Start_Pass_2.txt
                if %error1eve1%==0 (
                    SLEEP 3
                    "D:\dbStatusChecker\dbFi1estatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Start_Pass_3.txt
                    findstr /m "up to date" dbstatus_uTorrent_Start_Pass_3.txt
                    if %error1eve1%==0 (
                        D:
                        cd\
                        cd Dropbox
                        cd uTorrent
                        start uTorrent.exe
                        ) else (
                        SLEEP 1
                        GOTO STARTSTARTING
                        ) else (
                    SLEEP 1
                    GOTO STARTSTARTING
                    ) else (
                SLEEP 1
                GOTO STARTSTARTING
                ) else (
            SLEEP 1
            GOTO STARTEXITING
            ) else (
        SLEEP 1
        GOTO STARTEXITING
        ) else (
    SLEEP 1
    GOTO STARTEXITING

---

为了伟大的正义：此文字由 http://i.stack.imgur.com/RgsId.png 进行 OCR 编辑

Answer 1

cmd 可以很好地处理嵌套的ifs。你的问题是另一个问题。目前所有你的if检查，除了第一个不会做你想做的事。

通过放置一个

来使用延迟扩展

setlocal enabledelayedexpansion

在批处理文件的顶部并使用!errorlevel! 而不是%errorlevel%。

但是，由于您只检查 Errorlevel 是否为 0，因此您也可以这样做

if not errorlevel 1 ...

而不是

if %errorlevel%==0

Answer 2

乔伊诊断出一个与延迟扩张有关的问题。您还有另一个 - 您不应该在 IF ELSE 块中放置标签 - 您很可能不会得到您想要的结果。见https://stackoverflow.com/a/8481978/1012053。

Christian 有一个很好的建议来重组你的代码以摆脱嵌套。

由于您只是在增加睡眠间隔的情况下执行相同的命令，因此您可以使用 FOR /L 循环来进一步简化您的代码。

@echo off

:startExiting
set started=
for /l %%N in (1 1 3) do (
  if defined started sleep %%N
  set started=1
  "D:\dbStatusChecker\dbFileStatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Exit_Pass_%%N.txt
  findstr /m "up to date" dbstatus_uTorrent_Exit_Pass_%%N.txt || goto :startExiting
)

process -q uTorrent.exe 15

:startStarting
set started=
for /l %%N in (1 1 3) do (
  if defined started sleep %%N
  set started=1
  "D:\dbStatusChecker\dbFileStatus.exe" "D:\Dropbox" > dbstatus_uTorrent_Start_Pass_%%N.txt
  findstr /m "up to date" dbstatus_uTorrent_Start_Pass_%%N.txt || goto :startStarting
)

d:
cd \Dropbox\uTorrent
start uTorrent.exe

Answer 3

既然所有的else 子句都以goto 结尾，为什么不把它们全部颠倒过来，这样你就可以消除嵌套了。

如果代码有效，则工作完成。如果它仍然不起作用，那就少考虑一个因素。