范围如何在 .cmd 文件中工作？

Question

我有一个 .cmd 文件脚本，我运行它来检查用户是否在 AD 组中。

过程是这样的：

1. 更新他们的广告组列表
2. 检查他们是否有正确的组来安装应用程序
3. 如果函数的结果是N，则跳到下一个检查

这是我的脚本：

REM ======== SET variables ========
SET @ADGroups=C:\APPS\%USERNAME%\ADGroups.txt


REM ========  update AD groups ========
gpresult /r  > %@ADGroups% 


REM ======== APP1 =========
call:Check_ADGroup "App1 Name"
IF %@InGroupYN% == Y  (
    call:Install_App
) 

REM ======== APP2 =========
call:Check_ADGroup "App2 Name"
IF %@InGroupYN% == Y  (
    call:Install_App
) 

---

::--------------------------------------------------------
::-- Function Check In AD GROUP
::--------------------------------------------------------
:Check_ADGroup

SET @Result=[]
SET @InGroupYN=N

FOR /F "delims=" %%a in ('FINDSTR /rc:"%~1" %@ADGroups%') DO SET @Result=%%a


IF @Result == [] (
    REM ======== Set to No ======== 
    SET @InGroupYN=N

) ELSE (
    REM ======== Set to Yes ======== 
    SET @InGroupYN=Y
)
goto:eof

由于某种原因，@InGroupYN 始终以 Y 运行，无论函数返回 true 还是 false

命令行中的变量是否需要考虑一些作用域？

Answer 1

不改变你的结构……

为什么不像这样使用If Defined：

Rem ======== SET variables ========
Set "@ADGroups=C:\APPS\%UserName%\ADGroups.txt"

Rem ========  update AD groups ========
GPResult /R > "%@ADGroups%"

Rem ======== APP1 =========
Call :Check_ADGroup "App1 Name"
If Defined @InGroupYN (
    Call :Install_App
)

Rem ======== APP2 =========
Call :Check_ADGroup "App2 Name"
If Defined @InGroupYN (
    Call :Install_App
)

---

然后删除不必要的For循环和If/Else，改用条件Set：

Rem ------------------------------------------------------
Rem -- Function Check In AD GROUP
Rem ------------------------------------------------------
:Check_ADGroup

Rem ======== Undefine Variable ========
Set "@InGroupYN="

Rem ======= Set to Yes if match =======
FindStr /IRC:"%~1" "%@ADGroups%" >Nul && Set "@InGroupYN=Y"

GoTo :EOF