防止在vim中重复使用hjkl移动键

Question

由于我经常不使用 vim 提供的出色动作和文本对象，（并且因为 "Holding down 'j' is a vim anti-pattern,"）我希望 vim 帮助我训练使用这些而不是使用 hjkl 更多连续多次。

当我开始使用 vim 时，我很生气，因为我没有使用 hjkl 来移动而是使用箭头键。作为提醒不要这样做，我重新映射箭头键以防止自己使用它们 - 我知道使用主行导航将是一个更好的长期计划，所以我切断了通过使用箭头键获得的积极强化键。

map <left> <nop>   
map <right> <nop>  
# I quickly removed nop's for up and down because using 
#  the mouse wheel to scroll is sometimes useful

我不再需要在我的 .vimrc 中进行这些映射，因为它工作得非常好，而且我很快就切换了，无需有意识地这样做。以类似的方式，我现在也想停止重复使用基本移动键hjkl。我的设想是这样的：

let g:last_mov_key = 'none'
let g:times_mov_key_repeated = 0
function! MovementKey(key)
    if (g:last_mov_key == a:key)
        let g:times_mov_key_repeated = g:times_mov_key_repeated + 1
    else
        let g:last_mov_key = a:key
        let g:times_mov_key_repeated = 0
    endif
    if g:times_mov_key_repeated > 3
        echo "Negative Reinforcement!"                             
    endif
endfunction

noremap j :call MovementKey('j')<CR>gj
noremap k :call MovementKey('k')<CR>gk
noremap h :call MovementKey('h')<CR>h
noremap l :call MovementKey('l')<CR>l

但这会在可视模式下中断，我想象在许多其他情况下，在某些情况下使用 vim 命令行会改变不应该的状态。我怎样才能约束自己不得不使用更复杂的动作？

编辑：为清楚起见，在前两个答案之后编辑了问题，段落重新排序。我希望 vim 提供一些帮助，超越 romainl 的“0 级”。到目前为止，答案建议我不要浪费我的时间，但是如果我们假设我是学习技术的粉丝，我通过改变我的环境来改变我的习惯来改变激励机制呢？在这个模型中，我想完成一项任务，比如向下滚动一个页面，我会或多或少地随机尝试组合键，直到完成该任务。我大脑中的多巴胺信号等将加强最终实现这一结果的行动。我可以专注于记住不要使用hjkl，或者我可以专注于我最初尝试做的任务，编辑文本，并且不假思索地发现自己使用更有效的编辑技术。

Answer 1

你太听别人的话了。只需使用您最喜欢的任何键来移动，而不要理会其他键。重新映射 hjkl 键有点麻烦，最好不要这样做，因为由于历史原因，它们在 vim 中是 hardcoded。

Answer 2

我发现有效的一件事是:noremap jj <nop>。 Vim 会延迟 j 动作，因为它认为你可能正在扩展它，这会减慢你的速度以尝试其他方式。您也不能再按住 j 键，因为它只会触发 nop。您仍然可以在紧急情况下使用该按钮，但它令人沮丧，以至于您在日常编辑中避免使用它。

Answer 3

编辑

在阅读了您的编辑和您的评论后，我提出了激进的解决方案：重新映射hjkl 来做超级烦人的事情：

nnoremap h $
nnoremap l 0
nnoremap j gg
nnoremap k G
" and so on for other modes

hjkl 被映射到与其原始行为相反的极端，基本上使它们完全无法使用。为了完整性，您也应该对它们的同义词（:h h、:h j、:h k、:h l）执行相同的操作，但在某些情况下逐字符/逐行移动很有用。在这种情况下，您会很高兴拥有+ 或- 或<Space>。

不过，我不太喜欢那种巴甫洛夫式的方法。我觉得它太残酷了，而且你实际上习惯这些奇怪的映射的风险似乎很高。

结束编辑

短版：

箭头键和hjkl 都不值得使用，因此您的重新映射最终毫无用处。一段时间后你会习惯 Vim 的动作和文本对象。在此期间使用你觉得更自然的东西。不要着急。它会来。自然而然。

加长版：

您是打字员吗？或者你打算学习触摸打字吗？

我不是打字员，我也不打算成为一名打字员：我使用hjkl 只是为了在插入模式下实际输入hjkl。

当我需要在没有特定“目标”的情况下向上或向下移动 1 或 2 行时，我使用箭头键，当我需要向左或向右移动几个字母时，我使用箭头键。这样做并不丢人。

但是有一个问题，当你输入jjjjjjjjjj或者按10次向下箭头键向下移动10行时：jjjjjjjjjjj显然和↓一样糟糕↓↓↓↓↓↓↓↓↓

“不要使用箭头键”这个愚蠢的口头禅只是隐藏森林的树：它重复得如此频繁，以至于它让你专注于无用的模式/反模式，而不是真正学习更强大的方法。

我不想解释美丽的Your problem with Vim is that you don't grok vi.，但您可以将其视为“启蒙水平”：

• 0级将是

  jjjjjjjjjjj 或 ↓↓↓↓↓ ↓↓↓↓↓ 然后进行所有必要的水平运动以达到您的目标。

  阅读上面的行，hjkl 与 ←↓↑→ kbd> 辩论是绝对愚蠢的？

  无论您使用一种方法还是另一种方法，您最终都会将键盘垂直和水平移动以达到您想要编辑的值。多么浪费。强迫自己使用一种方法而不是另一种方法是多么浪费时间和精力，因为两者都同样糟糕。

• 1 级将是

  10j22l 向下 10 行并到达您的目标右侧 22 个字符。虽然打字少了很多，但您现在必须计算行数和字符数，这并不是特别好。

• 2级将是

  10jwww 向下 10 行并到达您的目标右侧 3 个字 或 10jf# 向下 10 行并跳转到目标的第一个字母（十六进制颜色值）。

  嗯，这样好多了。

• 3 级将是

  /#<CR> 直接跳转到你的目标（一个十六进制颜色值，和以前一样）。如果它高于你当前的位置，你会做?#<CR>。

如果您是一名触控打字员，或者正在接受培训以成为一名打字员，那么争论就解决了：hjkl（或jkl;，有些人喜欢重新映射它们）快速而自然，您不需要箭头键如果不是，那么使用hjkl 优于 ←↓↑→ 的好处最多最小。

转而关注eEbBwWfFtT/?} 和公司。一点一点。不要“强迫”自己。

Answer 4

我想提出一个更符合OP思维方式的解决方案。

我也决定阻止某些动作，如果没有计数之前是一个好主意，正如 here 所讨论的那样。我也尝试过简单的直接重新映射，但这在许多情况下都不起作用，如 OP 所述。

但我确实终于想出了一个使用key maps that returned an expression的方法：

function! DisableIfNonCounted(move) range
    if v:count
        return a:move
    else
        " You can make this do something annoying like:
        " echoerr "Count required!"
        " sleep 2
        return ""
    endif
endfunction

function! SetDisablingOfBasicMotionsIfNonCounted(on)
    let keys_to_disable = get(g:, "keys_to_disable_if_not_preceded_by_count", ["j", "k", "l", "h", "gj", "gk"])
    if a:on
        for key in keys_to_disable
            execute "noremap <expr> <silent> " . key . " DisableIfNonCounted('" . key . "')"
        endfor
        let g:keys_to_disable_if_not_preceded_by_count = keys_to_disable
        let g:is_non_counted_basic_motions_disabled = 1
    else
        for key in keys_to_disable
            try
                execute "unmap " . key
            catch /E31:/
            endtry
        endfor
        let g:is_non_counted_basic_motions_disabled = 0
    endif
endfunction

function! ToggleDisablingOfBasicMotionsIfNonCounted()
    let is_disabled = get(g:, "is_non_counted_basic_motions_disabled", 0)
    if is_disabled
        call SetDisablingOfBasicMotionsIfNonCounted(0)
    else
        call SetDisablingOfBasicMotionsIfNonCounted(1)
    endif
endfunction

command! ToggleDisablingOfNonCountedBasicMotions :call ToggleDisablingOfBasicMotionsIfNonCounted()
command! DisableNonCountedBasicMotions :call SetDisablingOfBasicMotionsIfNonCounted(1)
command! EnableNonCountedBasicMotions :call SetDisablingOfBasicMotionsIfNonCounted(0)

DisableNonCountedBasicMotions

请注意，为了方便起见，此处包含代码，但我也会与gist 联系以查看是否有更新/修复。

您可以放松水平运动的约束，或者 通过设置键/命令列表添加/删除其他动作 在您的~/.vimrc 中生效，g:keys_to_disable_if_not_preceded_by_count。 例如，以下仅对“j”和“k”强制执行以计数为前缀的运动：

let g:keys_to_disable_if_not_preceded_by_count = ["j", "k"]

此外，正如 gist 中所述，您可能会发现在您的 ~/.vimrc 以及上面的代码中添加类似的内容非常有用：

set number
if has('autocmd')
augroup vimrc_linenumbering
    autocmd!
    autocmd WinLeave *
                \ if &number |
                \   set norelativenumber |
                \ endif
    autocmd BufWinEnter *
                \ if &number |
                \   set relativenumber |
                \ endif
    autocmd VimEnter *
                \ if &number |
                \   set relativenumber |
                \ endif
augroup END

或者安装一个插件行vim-numbers。

尽管这个问题已经（很长时间）得到了 OP 对替代方法的满意度的回答，但我还是在这里添加了我的解决方案，以防有人正在寻找不同的东西。

Answer 5

我刚刚找到的一个非常特定于平台的解决方案，仅限 Mac：使用类似 vim 的东西（我只在 vim 模式下使用 PyCharm），打开 MacOS 键保持*，这使得按住 e 调出èéêëēėę 供您选择。这使得按住键永远不起作用！这真的很烦人除非你试图学会停止按住键！

如果我能弄清楚如何在我的终端仿真器（iTerm、Terminal.app 等）中使其工作，那么它可能在普通 vim 中工作？

*这会打开此功能，以防它被您禁用： defaults write -g ApplePressAndHoldEnabled -bool true