Delphi 7 - ShellExecute 命令在某些情况下不起作用

Question

我制作了一个游戏启动器，我使用这个命令：

 procedure TFMain.ImgBtn1Click(Sender: TObject);
     begin
      ShellExecute(TForm(Owner).Handle, nil, 'starter.exe', '-lang rus', nil, SW_SHOWNORMAL);
     end;

使用“-lang rus”作为参数。一切正常。游戏启动，语言为俄语（如果我输入“-lang eng”，它仍然可以正常工作，并且游戏是英文的）。

starter.exe 应用程序位于名为“bin”的文件夹中。当我想将启动器重新定位到此文件夹之外时，我使用此命令：

procedure TFMain.ImgBtn1Click(Sender: TObject);
     begin
      ShellExecute(TForm(Owner).Handle, nil, 'bin\starter.exe', '-lang rus', nil, SW_SHOWNORMAL);
     end;

然后游戏没有启动。实际上什么也没发生。 我应该改变什么？

Answer 1

您必须使用您尝试启动的应用程序的完整路径。

ExtractFilePath(Application.ExeName) 将为您提供启动器 exe 的完整路径。

解决方案一：使用ShellExecute

procedure TFMain.ImgBtn1Click(Sender: TObject);
var 
  ExecuteResult: integer;
  Path: string;
begin
  Path := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName));
  ExecuteResult := ShellExecute(0, nil, PChar(Path + 'bin\starter.exe'), '-lang rus', nil, SW_SHOWNORMAL);
  if ExecuteResult <= 32 then ShowMessage('Error: ' + IntToStr(ExecuteResult));
end;

您可以在以下位置找到错误代码列表：ShellExecute function documentation

最常见的错误代码：

• ERROR_FILE_NOT_FOUND 0x2
• ERROR_PATH_NOT_FOUND 0x3

解决方案 2： 使用 ShellExecuteEx

var
  FileName, Parameters, Folder: string;
  sei: TShellExecuteInfo;
  Error: DWORD;
  OK: boolean;
begin
  Folder := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName)) + 'bin\';
  FileName := Folder + 'starter.exe';
  Parameters := '-lang rus';
  ZeroMemory(@sei, SizeOf(sei));
  sei.cbSize := SizeOf(sei);
  sei.lpFile := PChar(FileName);
  sei.lpParameters := PChar(Parameters);
  sei.lpDirectory := PChar(Folder);
  sei.nShow := SW_SHOWNORMAL;
  OK := ShellExecuteEx(@sei);
  if not OK then
    begin
      Error := GetLastError;
      ShowMessage('Error: ' + IntToStr(Error));
    end;
end;

ShellExecuteEx documentation

解决方案 3： 使用CreateProcess

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: pchar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := pchar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, pchar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

procedure TForm1.Button4Click(Sender: TObject);
var
  FileName, Parameters, Folder: string;
  Error: integer;
  OK: boolean;
begin
  Folder := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName)) + 'bin\';
  FileName := Folder + 'starter.exe';
  Parameters := '-lang rus';
  OK := ExecuteProcess(FileName, Parameters, Folder, false, false, false, Error);
  if not OK then
    begin
      Error := GetLastError;
      ShowMessage('Error: ' + IntToStr(Error));
    end;
end;

CreateProcess documentation

Answer 2

您应该使用完全限定（绝对）路径。例如，如果你知道路径是

C:\Program Files (x86)\My Company\My Game\bin\starter.exe

你应该传递那个字符串。当然，您应该从不硬编码这样的字符串，因为它在不同的系统上可能会有所不同。如果您的应用程序是通用应用程序启动器，您会从用户那里获得路径。如果您的应用程序启动了您自己公司的游戏，您必须想出一种巧妙的方式来传达路径。

从你的问题看不清楚，但如果bin\starter.exe 是相对于你的应用程序的路径，你可以使用

ExtractFilePath(Application.ExeName) + 'bin\starter.exe'

顺便说一句，您可以通过查看ShellExecute 的返回值自己弄清楚这一切。当然，你已经仔细阅读了ShellExecutedocumentation，所以你知道返回值是什么。因此，您很容易识别出ERROR_FILE_NOT_FOUND 并意识到您需要一个完全合格的路径。