仅当存在网址时才进行超链接..？答案

【问题标题】：Hyperlinking only if web address present..?仅当存在网址时才进行超链接..？
【发布时间】：2011-10-13 08:50:05
【问题描述】：

以下是示例 XML 文件 -

<?xml version="1.0" encoding="UTF-8"?>
<Catalog>
<Book>
   <AName>Steven Holzner</AName>
   <BName>Using XSLT</BName>
   <Pub>ABC Publication </Pub>
   <Web>http://www.ABCPub.com</Web>
</Book>
<Book>
   <AName>Steven Holzner</AName>
   <BName>Using HTML</BName>
   <Pub>XYZ Publication </Pub>
   <Web></Web>
</Book>
</Catalog>

如果给出了网址，我想超链接 Pub 名称，否则只有 Pub 名称没有链接...

我的 XSL 代码在这里 -

<xsl:template match="Catalog">
    <xsl:for-each select="Book">
    <p><a>
    <xsl:attribute name="href">
      <xsl:value-of select="Web"/>
    </xsl:attribute>

    <xsl:value-of select="Pub"/>
    </a></p>
    </xsl:for-each>
</xsl:template>

我想要关注 HTML 源代码 -

ABC 出版物

XYZ 出版物

现在，即使没有给出 Web 地址，这个 XSL 也会给出超链接标签。哪段代码可以满足需要..？

祝你有美好的一天 - 约翰

【问题讨论】：

好问题，+1。 XSLT 是一种功能强大且极具表现力的语言，无需任何条件、循环结构或单独的属性生成指令，就可以用最少的行数解决这个问题。

标签： xml xslt

【解决方案1】：

这可以通过一个非常简短的转换来实现——没有<xsl:for-each>，没有<xsl:if>，<xsl:choose>，<xsl:when>，根本没有<xsl:attribute>：：：：：：：：：： p>

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Book[Web/text()]">
     <p>
      <a href="{Web}">
       <xsl:value-of select="Pub"/>
      </a>
     </p>
 </xsl:template>

 <xsl:template match="Book">
     <p>
       <xsl:value-of select="Pub"/>
     </p>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Catalog>
    <Book>
        <AName>Steven Holzner</AName>
        <BName>Using XSLT</BName>
        <Pub>ABC Publication </Pub>
        <Web>http://www.ABCPub.com</Web>
    </Book>
    <Book>
        <AName>Steven Holzner</AName>
        <BName>Using HTML</BName>
        <Pub>XYZ Publication </Pub>
        <Web></Web>
    </Book>
</Catalog>

产生想要的正确结果：

<p>
   <a href="http://www.ABCPub.com">ABC Publication </a>
</p>
<p>XYZ Publication </p>

说明：模板模式匹配。

【讨论】：

最后是一些 AVT 的 :-) 非常好的 Dimitre。 +1
@Demitre...非常感谢... :)

【解决方案2】：

只测试网络是否充满了选择/何时/其他

<xsl:template match="Catalog">
    <xsl:for-each select="Book">
    <p><xsl:choose>
<xsl:when test="string(Web)"><a>
    <xsl:attribute name="href">
      <xsl:value-of select="Web"/>
    </xsl:attribute>

    <xsl:value-of select="Pub"/>
    </a>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="Pub"/>
</xsl:othwerwise>
</xsl:choose>
</p>
    </xsl:for-each>
</xsl:template>

【讨论】：

【解决方案3】：

<xsl:if test="Web != ''">
   <a> 
    <xsl:attribute name="href"> 
      <xsl:value-of select="Web"/> 
    </xsl:attribute>
    <xsl:value-of select="Pub"/> 
    </a>
</xsl:if>

^只有在有网址的情况下才会显示发布者，你想要的是一个 xsl:choose...

<xsl:choose>
    <xsl:when test="Web != ''">
        <a> 
        <xsl:attribute name="href"> 
          <xsl:value-of select="Web"/> 
        </xsl:attribute>
        <xsl:value-of select="Pub"/> 
        </a>
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="Pub"/>
    </xsl:otherwise>
</xsl:choose>

【讨论】：

非常感谢谢尔多，现在你的第二个对我来说就足够了。第一个将来可能会来救援；）..再次感谢..