表格格式化的awk解决方案

Question

有以下格式的表格。是否有可能有一个 AWK 脚本以排除仅包含数字“1”的列的方式来格式化表格？

ST L1 L2 L3 L4 L5
ST2 1 1 1 1 1
ST2 1 0 1 0 1
ST3 1 0 1 0 1
ST3 0 0 1 1 1
ST4 1 0 1 0 1
ST5 1 0 1 0 1
ST6 1 0 1 0 1
ST7 0 0 1 1 1
ST8 0 0 1 0 1
ST9 1 0 1 0 1

输出应该如下：

ST L1 L2 L4
ST2 1 1 1
ST2 1 0 0
ST3 1 0 0
ST3 0 0 1
ST4 1 0 0
ST5 1 0 0
ST6 1 0 0
ST7 0 0 1
ST8 0 0 0
ST9 1 0 0

我可以理解如何打印列的逻辑，就像结束块中的 NR 值一样，如果它等于每次找到 1 时应该递增的变量，对于给定列（标题 NR==1 和列 $1 除外），打印该列。我的麻烦在于实际上试图打印最后块中的列，因为我正在尝试使用数组并且我仍在学习 AWK 和数组。我确信有一些聪明的方法可以做到这一点，尽管甚至不使用数组并且只是改变 AWK 查看数据的方式。

Answer 1

awk '
NR==FNR {
    if (NR > 1) {
        for (i=1;i<=NF;i++) {
            if ($i != 1) {
                nonOnes[i]
            }
        }
    }
    next
}
{
    ofs=""
    for (i=1;i<=NF;i++) {
        if (i in nonOnes) {
            printf "%s%s", ofs, $i
            ofs=OFS
        }
    }
    print ""
}
' file file
ST L1 L2 L4
ST2 1 1 1
ST2 1 0 0
ST3 1 0 0
ST3 0 0 1
ST4 1 0 0
ST5 1 0 0
ST6 1 0 0
ST7 0 0 1
ST8 0 0 0
ST9 1 0 0

如果您不想在命令行上两次列出同一个文件，您可以调整以添加此 BEGIN 部​​分：

BEGIN { ARGV[ARGC] = ARGV[ARGC-1]; ARGC++ } 

Answer 2

这应该可以解决问题：

    {
        # store current line
        line[FNR] = $0

        if (FNR > 1) # skip header
        {
            # select columns
            for (i = 1 ; i <= NF ; i++)
            {
                if ($i != 1) selected[i] = 1
            }
        }
    }

END {
        for (li = 1 ; li <= FNR ; li++)
        {
            # parse current line
            $0 = line[li]

            # pick selected fields
            for (i = j = 1 ; i <= NF ; i++)
            {
                if (selected[i]) $(j++) = $i
            }

            # trim record to selection
            NF = j-1
            print
        }
    }

在埃德莫顿的话之后：

• 将 l 更改为不那么模棱两可的东西
• printf 确实是一个语句，但是添加括号也不会造成伤害，或者会不会？
• 同意print "" 优于printf "\n"
• 分号是可选的，但不会造成伤害。我觉得看起来像 C 的东西更舒服
• NR 是一个没有引起注意的错字（因为它产生了预期的输出纯属运气）。我是说 NF。
• 更改了逻辑，不再添加尾随空格（不再使用 printf）

第二批发言后：

• 更改了输出记录生成，以避免多余的分隔符。

非常感谢您的校对。距离我上一次认真编写鹰派编程已经快 15 年了，可悲的是，锈迹已经开始了。