如何合并这些代码，awk然后cut

Question

我在 Debian 中使用 awk。

输入

11.22.33.44#55878:
11.22.33.43#55879:
...
...
(smtp:55.66.77.88)
(smtp:55.66.77.89)
...
...
cpe-33-22-11-99.buffalo.res.rr.com[99.11.22.33]
cpe-34-22-11-99.buffalo.res.rr.com[99.11.22.34]
...

部分 sh 代码（在 Debian 中运行）

awk '/#/ {print > "file1";next} \
/smtp/ {print > "file2";next} \
{print > "file7"}' input
#
if [ -s file1 ] ; then
    #IP type => 11.22.33.44#55878:
    cut -d'#' -f1 file1 >> output
    rm -f file1
fi
#
if [ -s file2 ] ; then
    #IP type => (smtp:55.66.77.88)
    cut -d':' -f2 file2 | cut -d')' -f1 >> output
    rm -f file2
fi
#
if [ -s file7 ] ; then
    #IP type => cpe-33-22-11-99.buffalo.res.rr.com[99.11.22.33]
    cut -d'[' -f2 file7 | cut -d']' -f1 >> output
    rm -f file7
fi

然后输出

11.22.33.44
11.22.33.43
55.66.77.88
55.66.77.89
99.11.22.33
99.11.22.34

是否可以仅将这些代码与 awk 合并，例如

awk '/#/ {print | cut -d'#' -f1 > "file1";next} \
/smtp/ {print | cut -d':' -f2 | cut -d')' -f1 > "file2";next} \
{print | cut -d'[' -f2 file7 | cut -d']' > "file7"}' input

我是新手，对此一无所知， 搜索问题后，仍然没有帮助。 任何提示？ 谢谢。

最好的问候。

Answer 1

$ awk -F'[][()#]|smtp:' '/#/{print $1;next} /smtp/{print $3;next} /\[/{print $2}' input
11.22.33.44
11.22.33.43
55.66.77.88
55.66.77.89
99.11.22.33
99.11.22.34

要将其保存在文件output中：

awk -F'[][()#]|smtp:' '/#/{print $1;next} /smtp/{print $3;next} /\[/{print $2}' input >output

工作原理

• -F'[][()#]|smtp:'

  这会将字段分隔符设置为 (a) 任何字符 ][()# 或 (b) 字符串 smtp:。

• /#/{print $1;next}

  如果该行包含#，则打印第一个字段并跳到next 行。

• /smtp/{print $3;next}

  如果该行包含smtp，则打印第三个字段并跳到next 行。

• /\[/{print $2}

  如果该行包含[，则打印第二个字段。

变化

解决这个问题的方法不止一种，例如，使用稍微不同的字段分隔符，我们仍然可以得到想要的输出：

$ awk -F'[][()#:]' '/#/{print $1;next} /smtp/{print $3;next} /\[/{print $2}' input
11.22.33.44
11.22.33.43
55.66.77.88
55.66.77.89
99.11.22.33
99.11.22.34